如何使用 XML::Twig 获取内容？

Question

我的目标是start_tag_handler（见下文）在找到apps/title 标签时获取apps/title 内容（见下文示例XML）。

并且 end_tag_handler 在找到 apps/logs 标记时获取 apps/logs 内容。

但此代码返回 null 并退出。

这是用于解析的 Perl 代码（使用XML::Twig）###：

    #!/usr/local/bin/perl -w

    use XML::Twig;
    my $twig = XML::Twig->new(
                start_tag_handlers =>
                  { 'apps/title' => \&kicks
                  },
                twig_roots =>
                  { 'apps' => \&app
                  },
                end_tag_handlers =>
                  { 'apps/logs' => \&bye
                  }
                );
    $twig -> parsefile( "doc.xml");

    sub kicks {
        my ($twig, $elt) = @_;
        print "---kicks--- \n";
        print $elt -> text;
        print " \n";
    }

    sub app {
        my ($twig, $apps) = @_;
        print "---app--- \n";
        print $apps -> text;
        print " \n";
    }


    sub bye {
        my ($twig, $elt) = @_;
        print "bye \n";
        print $elt->text;
        print " \n";
    }

这是 doc.xml###：

    <?xml version="1.0" encoding="UTF-8"?>
    <auto>
      <apps>
        <title>watch</title>
        <commands>set,start,00:00,alart,end</commands>
        <logs>csv</logs>
      </apps>
      <apps>
        <title>machine</title>
        <commands>down,select,vol_100,check,line,end</commands>
        <logs>dump</logs>
      </apps>
    </auto>

这是控制台中的输出###：

    C:\>perl parse.pl
    ---kicks---

    ---app---
    watchset,start,00:00,alart,endcsv
    ---kicks---

    ---app---
    machinedown,select,vol_100,check,line,enddump

Answer 1

查看XML::Twig 的start_tag_handlers 文档：

使用 2 个参数调用处理程序：树枝和元素。此时元素为空，但它的属性已创建。

在调用start_tag_handlers 时，甚至还没有看到文本内容，因为解析开始标记（例如<title>，而不是结束标记</title>）已经刚刚完成。

end_tag_handlers 不提供元素文本的原因可能是为了对称:-)。

你想要的可能是改用twig_handlers：

my $twig = XML::Twig->new(
    twig_handlers => {
        'apps/title' => \&kicks,
        'apps/logs' => \&bye
    },
    twig_roots => {
        'apps' => \&app
    },
);

输出是：

---kicks--- 
watch 
bye 
csv 
---app--- 
watchset,start,00:00,alart,endcsv
---kicks--- 
machine 
bye 
dump 
---app--- 
machinedown,select,vol_100,check,line,enddump