在 SELECT 语句中将名称拆分为多个部分

Question

我似乎找不到关于将字符串拆分为我需要的部分的现有帖子。我在 SQL Server 中有一个数据库字段，其中包含“LastName FirstName MI”（没有逗号，只是分隔人名每个部分的空格）。我有以下 SQL 来获取名字和姓氏，但不知道如何获取中间名或中间名。

例如。能源部约翰B

SELECT
    RTRIM(LEFT([PATIENT_NAME], CHARINDEX(' ', [PATIENT_NAME]))) AS LastName,
    SUBSTRING([PATIENT_NAME], CHARINDEX(' ', [PATIENT_NAME]) + 1, LEN([PATIENT_NAME])) AS FirstName
FROM
    Clients

结果：

• 名字 = 约翰 B
• 姓氏 = Doe

如何在此SELECT 语句中仅返回不带中间名首字母的名字并从该字符串中获取“B”作为中间名？

Answer 1

您可以取右 1 个字符，也可以反转字符串取第一个字符。

SELECT RIGHT(LTRIM(RTRIM([Patient_Name])), 1) AS Middle_Initial

SELECT LEFT(REVERSE(LTRIM(RTRIM([Patient_Name]))), 1) AS Middle_Initial

至于从你的名字字符串中删除 MI，我会找到字符串的长度并取左边的 N-2 个字符，或者我会对空格进行 charindex，然后取那么多字符。综上所述：

DECLARE @name VARCHAR(100) = 'Smith David M      ' 

--Clean the string of leading/trailing whitespace
SELECT LTRIM(RTRIM(@name)) AS name_cleaned

--Find the first space to parse out the last name
SELECT CHARINDEX(' ', @name) AS first_space

--Select all chars before the first space
SELECT LEFT(LTRIM(RTRIM(@name)), CHARINDEX(' ', @name)-1) AS last_name

--Find the next space, use the starting location as the previous space and add 1
SELECT CHARINDEX(' ', @name, 7) AS second_space

--Select all chars between the spaces
SELECT SUBSTRING(@name, CHARINDEX(' ', @name)+1, CHARINDEX(' ', @name, 7) - CHARINDEX(' ', @name)) AS first_name

--Select the right most char for middle initial
SELECT RIGHT(LTRIM(RTRIM(@name)), 1) AS middle

Answer 2

您可以用句点字符 (.) 替换空格字符并使用 PARSENAME()。

请注意，这适用于名称的所有 3 个部分，而不仅仅是中间的首字母。

Answer 3

在姓氏上使用 CHARINDEX 时，您将使用它作为子字符串的长度。然后，在 FirstName 上，再次将其用作子字符串的起始位置。现在，中间的技巧，在 CHARINDEX 上，您必须包括起始位置，即 LEN 减去 LastName CHARINDEX。这将为您提供第二个空格，这是您要开始使用中间名的位置。

请看下面的例子：

DECLARE @tb TABLE (PATIENT_NAME varchar(250));
INSERT INTO @tb VALUES 
('Doe John B')

DECLARE 
    @LastName       INT
,   @Middle         INT 

SELECT 
    @LastName       =  CHARINDEX(' ', PATIENT_NAME)
,   @Middle         =  CHARINDEX(' ', PATIENT_NAME,  LEN(PATIENT_NAME) - CHARINDEX(' ', PATIENT_NAME))
FROM @tb


SELECT 
    SUBSTRING(PATIENT_NAME, 1, @LastName) LastName
,   SUBSTRING(PATIENT_NAME, @LastName, LEN(PATIENT_NAME) - @LastName) FirstName 
,   SUBSTRING(PATIENT_NAME, @Middle, LEN(PATIENT_NAME) - @Middle + 1 ) Middle  
FROM @tb   

我已经声明了一些变量来提高可读性，但是没有它们你也可以做到。

当然，LEFT 和 RIGHT 是获取姓氏和中间名的更简单方法。除了使用一些辅助函数，如REVERSE 和TRIM，但我更喜欢PARSENAME 作为一种更简单、更简洁的方法。
这是一个例子：

SELECT 
    PARSENAME(REPLACE(PATIENT_NAME,' ','.'),3) LastName
,   PARSENAME(REPLACE(PATIENT_NAME,' ','.'),2) FirstName
,   PARSENAME(REPLACE(PATIENT_NAME,' ','.'),1) Middle

Answer 4

由于您必须从字符串中提取的元素数量是固定的(3)，您可以使用基于 XML 的拆分：

DECLARE @clients TABLE (PATIENT_NAME nvarchar(max));
INSERT INTO @clients VALUES 
 ('  Doe    John  B     ')
,('    Doe    Jane  C  ')
,(' Doe    Jill     ')

;WITH Splitted
AS (
    SELECT PATIENT_NAME as ORIGINAL_PATIENT_NAME
         ,REPLACE(REPLACE(REPLACE(ltrim(rtrim(PATIENT_NAME)),' ','<>'),'><',''),'<>',' ') as PATIENT_NAME
        ,CAST('<x>' + REPLACE(REPLACE(REPLACE(REPLACE(ltrim(rtrim(PATIENT_NAME)),' ','<>'),'><',''),'<>',' '), ' ', '</x><x>') + '</x>' AS XML) AS Parts
    FROM @clients
    )
SELECT
     ORIGINAL_PATIENT_NAME 
    ,PATIENT_NAME
    ,Parts.value(N'/x[1]', 'nvarchar(max)') AS LAST_NAME
    ,Parts.value(N'/x[2]', 'nvarchar(max)') AS FIRST_NAME
    ,Parts.value(N'/x[3]', 'nvarchar(max)') AS MIDDLE_NAME
FROM Splitted

结果：

正如您所见，它甚至可以使用随机间隔的名称。