需要在 vbscript 中将文本文件从 UTF8 转换为 Unicode

Question

我在一个文件夹中有一堆文本文件，我需要将编码更改为 Unicode，而不是手动打开文件并将它们保存为 Unicode，我想要一个脚本来执行此操作。

这些文件目前采用 UTF-8 编码，而我极其有限的脚本能力无法弄清楚这一点。我发现下面的代码可以从 ANSI 转换为 Unicode，当我使用此代码时，它确实将其转换为 Unicode，但它会弄乱字符，因此转换实际上不起作用。有什么想法吗？提前致谢。

Set fso = CreateObject("Scripting.FileSystemObject")
Set oFolder = fso.GetFolder("C:\test")
Set oFiles = oFolder.files

For each file in oFiles
If Right(file.Name, 3) = "txt" Then
Set ANSIFile = fso.OpenTextFile(file.path, 1, False, False)
ANSIContent = ANSIFile.ReadAll
Set UNICODEFile = fso.OpenTextFile(file.path, 2, False, True)
UNICODEFile.Write ANSIContent
End If
Next

Answer 1

很遗憾，VBScript 本身不支持这种转换。不过，您可以使用 ADODB.Stream 对象：

Set stream = CreateObject("ADODB.Stream")
stream.Open
stream.Type = 2 'text
stream.Charset = "utf-8"
stream.LoadFromFile "C:\input.txt"
text = stream.ReadText
stream.Close

Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile("C:\output.txt", 2, True, True)
f.Write text
f.Close

或者更精简一点：

Set fso = CreateObject("Scripting.FileSystemObject")

Set stream = CreateObject("ADODB.Stream")
stream.Open
stream.Type = 2 'text
stream.Charset = "utf-8"
stream.LoadFromFile "C:\input.txt"
fso.OpenTextFile("C:\output.txt", 2, True, True).Write stream.ReadText
stream.Close

如果要替换现有文件，则必须使用第一个版本并使用相同的文件进行输入和输出。使用这样的循环遍历文件夹中的所有文件：

Set fso = CreateObject("Scripting.FileSystemObject")
Set stream = CreateObject("ADODB.Stream")

For Each f In fso.GetFolder("C:\source\folder").Files
  stream.Open
  stream.Type = 2 'text
  stream.Charset = "utf-8"
  stream.LoadFromFile f.Path
  text = stream.ReadText
  stream.Close

  fso.OpenTextFile(f.Path, 2, True, True).Write text
Next