将多维数组转换为 XML，然后使用递归 XSLT 函数答案

【问题标题】：Transform a multidimensional array to XML and then use a recursive XSLT function将多维数组转换为 XML，然后使用递归 XSLT 函数
【发布时间】：2011-08-08 11:15:15
【问题描述】：

我在 PHP 中有一个从给定路径检索所有目录和文件的函数。这会返回一个数组，例如：

array(
    "dirname1" => array(
        "dirname2" => array(
            "dirname3" => array(
                "0" => "file1",
                "1" => "file2",
                "2" => "file3"
            ),
            "0" => "file4",
            "1" => "file5",
            "2" => "file6",
            "dirname4" => array(
                "0" => "file7",
                "1" => "file8"
            )
        ),
        "0" => "file9",
        "1" => "file10"
    ),
    "0" => "file11",
    "1" => "file12",
    "2" => "file13"
);

我最终需要的是一个多维（不知道是否是确切的词）列表，其中包含使用 XSLT 1.0 从 XML 文件生成的 <ul /> 和 <li />，例如：

<ul>
    <li class="dirname">
        dirname1
        <ul>
            <li class="dirname">
                Dirname2
                <ul>
                    <li class="dirname">
                        Dirname3
                        <ul>
                            <li>file1</li>
                            <li>file2</li>
                            <li>file3</li>
                        </ul>
                    </li>
                    <li>file4</li>
                    <li>file5</li>
                    <li>file6</li>
                    <li class="dirname">
                        dirname4
                        <ul>
                            <li>file7</li>
                            <li>file8</li>
                        </ul>
                    </li>
                </ul>
            </li>
            <li>file9</li>
            <li>file10</li>
        </ul>
    </li>
    <li>file11</li>
    <li>file12</li>
    <li>file13</li>
</ul>

最后，在每个<li /> 中，我需要<a /> 中的路径，例如：

<li class="dirname"><a href="/dirname1">dirname1</a></li>

<li><a href="/dirname1/dirname2/dirname3/file1">file1</a></li>

<li><a href="/dirname1/file9">file9</a></li>

实际上，我没有需要转换的 XML，因为我不知道什么是好的结构，然后将其转换为 XSLT 1.0。我在<a /> 中有路径。如有必要，我可以使用 PHP 执行此操作，我可以在 PHP 中检测它是目录还是非目录，我们还可以在 XML 上添加一些内容来检测 class="dirname"。

我希望我已经提供了足够的信息来理解我。

提前谢谢你！

【问题讨论】：

Multidimensional array iteration 的可能重复项
@Gordon：我还需要 XSLT 中的递归函数，这不是他们在您的链接上要求的。不管怎样，谢谢你。 :)
@Gordon：抱歉，英语不是我的主要语言。 ul/li 输出列表需要从 XML 文件生成。我添加了这个：我最终需要的是一个多维（不知道是否是确切的单词）列表，其中包含
和
使用 XSLT 1.0 从 XML 文件生成

【解决方案1】：

隧道参数：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>
    <xsl:template match="node()|@*" name="identity">
        <xsl:param name="pPath"/>
        <xsl:copy>
            <xsl:apply-templates select="node()|@*">
                <xsl:with-param name="pPath" select="$pPath"/>
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="li[@class='dirname']">
        <xsl:param name="pPath"/>
        <xsl:call-template name="identity">
            <xsl:with-param name="pPath"
             select="concat($pPath,'/',normalize-space(text()[1]))"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template match="text()">
        <xsl:param name="pPath"/>
        <xsl:call-template name="text">
            <xsl:with-param name="pPath"
             select="concat($pPath,'/',normalize-space())"/>
        </xsl:call-template>
    </xsl:template>
    <xsl:template match="li[@class='dirname']/text()" name="text">
        <xsl:param name="pPath"/>
        <a href="{$pPath}">
            <xsl:value-of select="."/>
        </a>
    </xsl:template>
</xsl:stylesheet>

输出：

<ul>
    <li class="dirname">
        <a href="/dirname1">
            dirname1
        </a>
        <ul>
            <li class="dirname">
                <a href="/dirname1/Dirname2">
                    Dirname2
                </a>
                <ul>
                    <li class="dirname">
                        <a href="/dirname1/Dirname2/Dirname3">
                            Dirname3
                        </a>
                        <ul>
                            <li>
                                <a href="/dirname1/Dirname2/Dirname3/file1"
                                >file1</a>
                            </li>
                            <li>
                                <a href="/dirname1/Dirname2/Dirname3/file2"
                                >file2</a>
                            </li>
                            <li>
                                <a href="/dirname1/Dirname2/Dirname3/file3"
                                >file3</a>
                            </li>
                        </ul>
                    </li>
                    <li>
                        <a href="/dirname1/Dirname2/file4">file4</a>
                    </li>
                    <li>
                        <a href="/dirname1/Dirname2/file5">file5</a>
                    </li>
                    <li>
                        <a href="/dirname1/Dirname2/file6">file6</a>
                    </li>
                    <li class="dirname">
                        <a href="/dirname1/Dirname2/dirname4">
                            dirname4
                        </a>
                        <ul>
                            <li>
                                <a href="/dirname1/Dirname2/dirname4/file7"
                                >file7</a>
                            </li>
                            <li>
                                <a href="/dirname1/Dirname2/dirname4/file8"
                                >file8</a>
                            </li>
                        </ul>
                    </li>
                </ul>
            </li>
            <li>
                <a href="/dirname1/file9">file9</a>
            </li>
            <li>
                <a href="/dirname1/file10">file10</a>
            </li>
        </ul>
    </li>
    <li>
        <a href="/file11">file11</a>
    </li>
    <li>
        <a href="/file12">file12</a>
    </li>
    <li>
        <a href="/file13">file13</a>
    </li>
</ul>

【讨论】：

@Alejandro：感谢您的 XSLT。您的 XML 输入是什么样的？提前谢谢！
我试过这个输入，但我没有得到相同的输出：pastebin.com/Jj5gB2Nk
@udexter：我正在使用您发布的输入。您链接的新的没有任何@class 等于"dirname"。
@Alejandro：啊！那是最终需要的输出，我在 HTML 中需要的。我不知道用 XML 处理它以获得最终的 HTML 是一个很好的结构。你推荐一个更好的 XML 吗？
@udexter：只要包含所有信息，任何架构都可以工作......我们都在使用您发布的那个。如果这不是正确的，请更新。

【解决方案2】：

PHP 部分

function ulRenderer($dirs, $path = array()) {
    echo '<ul>';
    foreach ($dirs as $key => $value) {
        if (is_array($value)) {
            printf(
                '<li class="dirname"><a href="%s">%s</a>',
                implode('/', $path),
                $key
            );

            ulRenderer($value, array_merge(
                $path, array($key)
            ));
            echo '</li>';
        }
        else {
            printf(
                '<li><a href="%s/%s">%s</a></li>',
                implode('/', $path),
                $value, $value
            );
        }
    }
    echo '</ul>';
}

$dirs = array(
    "dirname1" => array(
        "dirname2" => array(
            "dirname3" => array(
                "0" => "file1",
                "1" => "file2",
                "2" => "file3"
            ),
            "0" => "file4",
            "1" => "file5",
            "2" => "file6",
            "dirname4" => array(
                "0" => "file7",
                "1" => "file8"
            )
        ),
        "0" => "file9",
        "1" => "file10"
    ),
    "0" => "file11",
    "1" => "file12",
    "2" => "file13"
);


ulRenderer($dirs);

XML/XSL 部分

dirs.xml

<?xml version="1.0" encoding="UTF-8" ?>
<root>
    <dir name="dirname1">
        <dir name="dirname2">
            <dir name="dirname3">
                <file>file1</file>
                <file>file2</file>
                <file>file3</file>
            </dir>

            <dir name="dirname4">
                <file>file4</file>
                <file>file5</file>
            </dir>

            <file>file6</file>
            <file>file7</file>
            <file>file8</file>
        </dir>

        <file>file11</file>
        <file>file12</file>
        <file>file13</file>
    </dir>
</root>

dirs.xslt

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="dir">
        <ul>
            <li>
                <a>
                    <xsl:attribute name="href">
                        <xsl:call-template name="path" />
                    </xsl:attribute>
                    <xsl:value-of select="@name" />
                </a>
                <xsl:apply-templates />
            </li>
        </ul>
    </xsl:template>

    <xsl:template match="file">
        <li>
            <a>
                <xsl:attribute name="href">
                    <xsl:call-template name="path" />
                </xsl:attribute>
                <xsl:value-of select="." />
            </a>
        </li>
    </xsl:template>

    <xsl:template name="path">
        <xsl:if test="parent::dir">
            <xsl:for-each select="ancestor::dir">
                <xsl:sort select="position()" order="ascending"/>
                <xsl:value-of select="@name" />
                <xsl:text>/</xsl:text>
            </xsl:for-each>
        </xsl:if>
        <xsl:choose>
            <xsl:when test="name() = 'dir'">
                <xsl:value-of select="@name" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

又是 php

$dom = new DOMDocument;
$dom->load('dirs.xml');

$xsl = new DOMDocument;
$xsl->load('dirs.xslt', LIBXML_NOCDATA);

$xslt = new XSLTProcessor();
$xslt->importStylesheet($xsl);

echo $xslt->transformToXML($dom);

【讨论】：

谢谢！这将有助于生成 XML 结构。现在看看是否有人可以帮助我处理 XSLT 部分！