基于单元格值隐藏行非常慢

Question

我有工作代码可以根据相应的单元格值隐藏/取消隐藏行。

这是一个材料清单，有一个“完成”按钮。您按下按钮，应隐藏数量 = 0 的任何行。

有 400 多行，我可以看到这些行消失了。它每秒处理大约 20 行，这使得完成列表需要超过 20 秒。该列表每隔几个月就会翻一番。

还有其他方法可以更快地隐藏线条吗？

隐藏：

Public Sub HideRows()
Dim cell As Range
For Each cell In ActiveSheet.Range("H18:H469")
    cell.EntireRow.Hidden = (cell.Value = 0 And cell.Value <> "")
Next cell
End Sub

取消隐藏：

Public Sub UnhideRows()
Dim cell As Range
For Each cell In ActiveSheet.Range("H18:H469")
    If (cell.Value = 0 And cell.Value <> "") Then cell.EntireRow.Hidden = False
Next cell
End Sub

Answer 1

在代码开始时关闭屏幕更新和手动计算。确保在代码末尾重新打开 if。

    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
    '...your code...
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True

Answer 2

我只是像 cmets 中出现的那样打字。使用 Union 收集合格范围并一次性隐藏。我不确定您为什么要进行双重测试。 = 0 还不够吗？或者正如@Marcucciby2 询问的那样，您是否打算使用 Or？

正如在其他答案中提到的，您可以通过切换 ScreenUpdating、pageBreaks 和切换到手动计算模式来进行一些优化。

如果可能，请摆脱该 ActiveSheet 引用并使用实际的工作簿和工作表引用。

Option Explicit
Public Sub HideRows()
    Dim cell As Range, unionRng As Range
    For Each cell In ActiveSheet.Range("H18:H469")
        If cell.Value = 0 Then
            If Not unionRng Is Nothing Then
                Set unionRng = Union(unionRng, cell)
            Else
                Set unionRng = cell
            End If
        End If
    Next
    If Not unionRng Is Nothing Then unionRng.EntireRow.Hidden = True
End Sub