变量设置在 for 循环内设置时表现出意外行为

Question

我正在修改批处理脚本以将文件位置传递给 makefile（使用 nmake 运行）。 for 循环应该循环可用驱动器并搜索文件（如果之前没有设置）。批处理不是我有太多经验的东西，所以希望有人能发现发生了什么。

当我在遍历驱动器的 for 循环之外设置 winbison 时，变量将设置为 win_bison.exe 的路径。当我在 for 循环中设置它时，我得到“ECHO 开启”。我认为这是批处理如何处理解析/扩展的一个症状。我设置了 EnableDelayedExpansion 但得到了相同的结果。

这是我的代码。

@ECHO OFF
setlocal EnableDelayedExpansion
set currentDir=%cd%
set winbison=
set winflex=

set drives=
for /f "delims=" %%a in ('fsutil fsinfo drives') do @set drives=%%a

REM :~8 is to slice off "Drives: " returned by fsutil
for %%i in (%drives:~8%) do (
    chdir /d %%i
    if not defined [%winbison%] (
        set winbison=
        for /f "delims=" %%a in ('dir win_bison.exe /s /b 2^>nul') do @set winbison=%%a
    @ECHO ON
        echo test
        echo %winbison%
    @ECHO OFF
    )

    if not defined [%winflex%] (
        set winflex=
        for /f "delims=" %%a in ('dir win_flex.exe /s /b 2^>nul') do @set winflex=%%a
    )
)

chdir /d %currentDir%

@ECHO ON
echo %winbison%
... stuff gets passed to nmake.

Answer 1

下一个脚本可以运行：

@ECHO OFF
setlocal enableextensions EnableDelayedExpansion
set "currentDir=%cd%"
set "winbison="
set "winflex="

set "drives="
for /f "delims=" %%a in ('fsutil fsinfo drives') do @set "drives=%%a"

REM :~8 is to slice off "Drives: " returned by fsutil
for %%i in (%drives:~8%) do (
  if exist %%iNUL (
    pushd %%i
    if not defined winbison (
      for /f "delims=" %%a in (
        'dir win_bison.exe /s /b 2^>nul') do @set "winbison=%%a"
      echo [debug] %%i winbison=!winbison!
    )

    if not defined winflex (
      for /f "delims=" %%a in (
        'dir win_flex.exe /s /b 2^>nul') do @set "winflex=%%a"
      echo [debug] %%i winflex=!winflex!
    )
    popd
  )
)

echo [debug] winbison=%winbison%
echo [debug] winflex=%winflex%

rem ... stuff gets passed to nmake

在上面的代码sn-p中：

• 在所有set "variable=value" 中加上引号以避免（意外忘记）尾随空格；
• if exist %%iNUL 避免可能出现的The device is not ready 错误消息；
• 正确的语法if not defined winbison等；
• 必要时!variable! 而不是%variable%（阅读EnableDelayedExpansion）；
• 使用pushd ... popd 对而不是cd /D。