如何在 Haskell 中“重载”美元运算符

Question

首先，很抱歉，如果这个问题已经被问到，我根本找不到合适的英文术语来表达我的意思。

我想知道 Haskell 中是否有任何类型类表示函数应用程序，以便为不同的数据类型定义多种行为。

使用Graphics.X11.Xlib 包，我遇到了许多要求完全相同参数的不同函数。所以我的想法是将这些函数打包成一个元组（因为它们的返回类型不一样），并一次性将它们全部提供参数。像这样：

import Graphics.X11.Xlib

main = do
  display <- openDisplay ":0"
  let dScreen = defaultScreen display
      (black, white, cMap) =
      -- here is where the "parameter dispatch" is needed
      (blackPixel, whitePixel, defaultColormap)  display dScreen

  -- computation
  return ()

我没有找到任何东西，所以我决定创建这种类型类：

{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances, FunctionalDependencies #-}
import Graphics.X11.Xlib

class Dispatch f x y | x y -> f where
  dsp :: f -> x -> y
instance Dispatch (a -> b, a -> c, a -> d) a (b, c, d) where
  dsp (f, g, h) x = (f x, g x, h x)

main = do
  display <- openDisplay ":0"
  let dScreen = defaultScreen display
      (black, white, cMap) =
      -- here is where the "parameter dispatch" is needed
      (blackPixel, whitePixel, defaultColormap) `dsp` display `dsp` dScreen

  -- computation
  return ()

它工作得很好，并且通过为不同的元组大小乘以实例，可以根据需要的值简单地从“函数元组”中添加或删除函数，并且代码仍然可以编译。

但是如果没有这种解决方法，有没有办法做到这一点？ 我尝试使用Control.Applicative 或Control.Arrow，但多个参数函数最终效果不佳。

到目前为止我最好的尝试是：(,) <$> blackPixel <*> whitePixel

Answer 1

这不是一个真正的答案，但您可以通过以下方式将此想法扩展到真正的“$ 运算符的重载”：

{-# LANGUAGE TypeFamilies, FlexibleInstances #-}

import Prelude hiding (($))

infixr 0 $

class Dispatch f where
  type Argument f :: *
  type Result f :: *
  ($) :: f -> Argument f -> Result f

instance Dispatch (a -> b) where
  type Argument (a->b) = a
  type Result (a->b) = b
  f $ x = f x

instance (Dispatch x, Dispatch y, Argument x ~ Argument y)
            => Dispatch (x,y) where
  type Argument (x,y) = Argument x
  type Result (x,y) = (Result x, Result y)
  (f,g) $ a = (f $ a, g $ a)

instance ( Dispatch x, Dispatch y, Dispatch z
         , Argument x ~ Argument y, Argument y ~ Argument z )
            => Dispatch (x,y,z) where
  type Argument (x,y,z) = Argument x
  type Result (x,y,z) = (Result x, Result y, Result z)
  (f,g,h) $ a = (f $ a, g $ a, h $ a)

main :: IO ()
main = do
   print $ ((\x -> ((2*x+),(3*x+)), (**), logBase) $ 2) $ 4

((8.0,10.0),16.0,2.0)

Answer 2

您可以使用liftA 系列函数将多个函数应用于单个参数。嵌套它们以将许多函数应用于许多参数。所以：

(b, w, m) = liftA3 (liftA3 (,,)) blackPixel whitePixel defaultColormap display dScreen