为批处理文件转义括号内的括号

Question

这就是我想要做的：

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something (like this)
)|clip

因此将其复制到剪贴板中。我尝试了以下方法：

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something ^(like this^)
)|clip

但这似乎也影响了我的 WANTED 括号，因为我收到了一个错误。为了测试这一点，我简单地完成了：

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something ^(like this^)
FFF
)|clip

嘿！这几乎可行，文本一直复制到“this”中的“s”。它不复制最后的括号，或者显然是 F。有什么想法吗？

Answer 1

很明显你需要三个插入符号:-)

(
@echo This is some code that is
@echo Important to echo exactly as-is
@echo Even if I use parenthesis
@echo for something (like this^^^)
)|clip

为什么？这有点棘手……

首先解析器解析块并将this^^^)部分转义为this^)，括号第一次在这里转义。

但是当您使用管道时，整个块将被转换并传输到新的 cmd.exe 实例。
C:\Windows\system32\cmd.exe /S /D /c" ( @ echo This is some code is ... & @ echo for something (like this^) )"

在新实例中，需要再次转义右括号。
就是这样！

有关更多信息，您可以阅读类似的问题
SO: why does delayed expansion fail when inside a piped block of code

Answer 2

如果您对插入符号计数感到困惑，请记住它始终是2 减 1 的幂。或者，请记住，第一次加 2，第二次加 4，第三次加 8，...

例如，（在 XP 上测试）

(
for /f "tokens=* delims=" %%S in (
'echo X^^^^^^^^^^^^^^^& ^^^^^^^^^^^^^^^| ^^^| find " "'
) do @echo %%S
) | find "X"

当 DOS 解析批处理文件时，首先会正常读取 echo 语句 (1)，其次是因为它是管道内部命令（DOS 似乎希望管道中的程序，而内部命令不是程序）(3)，第三是因为它在一个“for /f”命令驱动的单词列表中（参见 for /?）（7），第四次出现在这个线程中已经给出的原因（15）。

我个人也可能注意到，我认为仅仅因为 DOS 碰巧忽略了在特定情况下丢失的转义，所以将热字符的正确转义排除在外是一种草率的编码。因此，如果我想在上面的例子中呼应一对圆括号，我会给每 15 个插入符号，即使左括号不需要它。那么任何阅读我的代码的人都不必想知道为什么一个括号被引用而另一个不是。以及如何修改代码修改下的引用。

Answer 3

三重插入符号并非在所有情况下都有效。采取以下措施：

IF EXIST file.txt (
ECHO ...OK
) ELSE (
ECHO TEST THIS: (SOME WORDING! ^^^)   > file.txt
)

file.txt 的内容是：

TEST THIS: (SOME WORDING! ^)

Answer 4

当我需要在封装的回声中使用右括号时，我的解决方案是在脚本开头创建一个名为 %endPar% 的变量，如下所示：

@set "endPar=)"
@echo This is some code that is>tmp
@echo Important to echo exactly as-is>>tmp
@echo Even if I use parenthesis>>tmp
@echo for something (like this%endPar%>>tmp
@type tmp|clip
@del tmp

我稍微改了一下，测试了两次。

代码只是将回显输出到一个名为 tmp 的文件，然后您将文件的内容通过管道传输到剪辑，然后您就可以将其粘贴到您想要的任何位置。