将 On Error Resume Next 与 If 语句一起使用

Question

由于 On Error Resume Next 继续执行下一条语句而不是下一行，是否有人对将它与 If 语句一起使用有任何建议？

On Error Resume Next
For i = 1 To r
    If dataArray(i,1) <10 Then
        intA = intA + 1
    End If
    If dataArray(i,2) <10 Then intB = intB + 1
    If dataArray(i,2) <10 Then _
        intC = intC + 1: intD = intD + 1
Next i
On Error GoTo 0

上面每种风格的If语句，在出错的情况下依然会进行加法，比如元素dataArray(i,1)包含文本。这可以通过错误处理程序来解决，但如果有多个 If 语句，这会变得混乱。有人有什么建议吗？

Answer 1

严格对您的问题的回答如下：

Option Explicit

Sub main()
    Dim dataArray As Variant
    Dim i As Long, r As Long, intA As Long, intB As Long, intC As Long, intD As Long

    dataArray = Range("A1:D5").Value
    r = UBound(dataArray)
    On Error GoTo SKIP
    For i = 1 To r
        If dataArray(i, 1) < 10 Then intA = intA + 1

        If dataArray(i, 2) < 10 Then
            intB = intB + 1
            intC = intC + 1
            intD = intD + 1
        End If
SKIP:
    Next i
    ' On Error GoTo 0 '<--| you can comment this out being the last statement since upon exiting the default error handling is resumed 

End Sub

Answer 2

如果您希望数组指定位置上的数字值实际上不需要构建庞大的错误处理程序或使用 GoTo，您可以检查变量的Type！ 所以，例如：

For i = 1 To r
    If IsNumeric(dataArray(i,1)) And Not IsString(dataArray(i,1)) Then
        If dataArray(i,1) <10 Then
            intA = intA + 1
        End If
        If dataArray(i,2) <10 Then intB = intB + 1
        If dataArray(i,2) <10 Then _
            intC = intC + 1: intD = intD + 1
    End If
Next i

Public Function IsString(ByRef var as Variant) as Boolean
    IsString = (TypeName(var) = "String")
End Function

如您所见，您可以检查IsNumeric，并且由于字符串可以是数字，因此显式检查Not IsString。

由于不仅字符串可以从 IsNumeric 函数（例如字符）返回 True，因此还有办法修改示例并扩展您自己的函数！

链接： TypeName, IsNumeric

另一个示例（仅带一个小数点的数字并允许使用字符串）。 那么如果输入看起来像什么：

例子：

Sub AcceptOnlyNumbers()
'pass only strings that can be threaten as doubles
    Dim rng As Range
    Dim cl As Range

    Set rng = Sheets(1).[A1:A8]

    For Each cl In rng
        With cl
        If Not (IsNumeric(.Value2) Or (IsNumeric(Val(.Value2)) And _
            Len(.Value2) = Len(CStr(Val(.Value2))))) And .Value2 <> vbNullString Then
                Debug.Print .Value2, "is filtered"
            Else
                Debug.Print .Value2, "is passed"
            End If
        End With
    Next

End Sub

输出：

然后我们可以使用CDbl（如果十进制是逗号）或Val（如果十进制-点）转换字符串。随意玩弄它！例如，如果您不需要十进制数字，您可以在此之后添加另一个检查（或者，再次构建您自己的 - 所有这些只是示例，您可以在开始时检查整数）：

Public Function IsWholeNumber(ByVal expDbl As Double) as Boolean
    IsWholeNumber = (Int(expDbl) = expDbl)
    'or more bulky but ok too: IsWholeNumber = InStr(Str(expDbl), ".") = 0
End Function

请注意这一事实，在点十进制国家CDbl 与点配合得很好，而我的示例则不同（带逗号的值也被过滤掉了）。

• Val、Str 将始终使用美国设置（点为十进制）。

• CDbl、CStr 将考虑区域设置。

链接： Val, Writing International Code