Excel VBA - 网页抓取 - 跟踪包裹 - 处理跟踪号不正确的错误

Question

我正在尝试创建一个函数，该函数通过使用跟踪号来获取空运单的状态。 在 stackoverflow 社区的帮助下，我设法创建了一个正确获取状态的函数。

但是，我正在尝试添加跟踪号可能不正确的错误处理。 使用当前函数，如果跟踪号有效，它会正确获取结果。 但是当提供的数字不正确时，该函数会返回一个 0 值并在后台循环运行。从 VBA 编辑器停止时，excel 崩溃。

这是迄今为止我想出的代码。任何添加此错误处理的帮助将不胜感激。 样品正确货号：92366691 样品错误货号：59473805

 Function FlightStat_AF(cargoNo As Variant) As String
 Dim url As String, ie As Object, result As String

  url = "https://www.afklcargo.com/mycargo/shipment/detail/057-" & cargoNo

  Set ie = CreateObject("InternetExplorer.Application")
  With ie
    .Visible = False
    .navigate url
    Do Until .readyState = 4: DoEvents: Loop
  End With
  'wait a little for dynamic content to be loaded
  Application.Wait (Now + TimeSerial(0, 0, 1))

  'Get the status from the table
  Do While result = ""
    DoEvents
    On Error Resume Next
     result = Trim(ie.document.getElementsByClassName("fs-12 body-font-bold")(1).innerText)
    On Error GoTo 0
    Application.Wait (Now + TimeSerial(0, 0, 1))
  Loop

  ie.Quit: Set ie = Nothing
  
  'Return value of the function
  FlightStat_AF = result
End Function

Answer 1

检查 url 是否有效的方法是使用下面的函数：

Public Function URLexist(urlToCheck  As String) As Boolean
    'source :  https://excel-malin.com

    On Error GoTo Err

    Dim oXHTTP As Object
    Set oXHTTP = CreateObject("MSXML2.XMLHTTP")

    oXHTTP.Open "HEAD", urlToCheck , False
    oXHTTP.send

    URLexist = (oXHTTP.Status = 200)
    Exit Function

    Err:
    URLexist = False
End Function

Answer 2

我今天学到了很多，对此我感到非常高兴。我的代码基于这个答案，我从^^
Scraping specific data inside a table II (Answer by SIM)

学到了所有新东西

您询问发送错误 ID 时如何避免错误。这是您如何处理该错误的答案，以及当您以错误的 ID 格式发送 ID 时出现的错误。

这是Sub()来测试功能：

Sub test()
  'A valid ID
  MsgBox FlightStat_AF("92366691")
  
  'A wrong ID
  'The whole string is "The provided AWB(s) is either invalid, not found or you are not authorized for it."
  'The function FlightStat_AF cuts the string by comma
  'So it delivers "The provided AWB(s) is either invalid"
  'I'am not clear with regex till now and used it like the macro this code is based on ;-)
  MsgBox FlightStat_AF("59473805")
  
  'Somthing else than a valid ID format
  MsgBox FlightStat_AF("blub")
End Sub

这是function() 以获得您想要的答案：

Function FlightStat_AF(cargoNo As Variant) As String

  Const url = "https://www.afklcargo.com/mycargo/api/shipment/detail/057-"
  Dim elem As Object
  Dim result As String
  Dim askFor As String
  
  With CreateObject("MSXML2.XMLHTTP")
    .Open "GET", url & cargoNo, False
    .send
    result = .responseText
    
    If .Status = 200 Then
      If InStr(1, result, "faultDescription") = 0 Then
        askFor = """metaStatus"""
      Else
        askFor = """faultDescription"""
      End If
      
      With CreateObject("VBScript.RegExp")
        .Global = True
        .MultiLine = True
        .Pattern = askFor & ":(.*?),"
        Set elem = .Execute(result)
      End With
      
      If Not elem Is Nothing Then
        result = Replace(elem(0).SubMatches(0), Chr(34), "")
      Else
        result = "No Value"
      End If
    Else
      result = "No cargoID"
    End If
  End With
  
  FlightStat_AF = result
End Function