在过程结束和错误处理程序中编写结束语句的好习惯是什么？

Question

我发现自己在过程结束和错误处理程序中都编写了一些命令。最重要的是，我发现自己在所有函数中都写了这些行：

    Application.Cursor = xlDefault
    Application.ScreenUpdating = True

ErrHandler:
    MsgBox ("An unforseen problem has occured. Please contact support.")
    Application.Cursor = xlDefault
    Application.ScreenUpdating = True
End Sub

我觉得我重复自己的次数超出了我的预期。在过程末尾和错误处理程序中编写这些“标准”行是否有更好的做法？

Answer 1

你可以简单地让你的错误处理程序在代码的“清理”部分恢复，当没有错误发生时也会执行：

   Clean_up:
        Application.Cursor = xlDefault
        Application.ScreenUpdating = True
        Exit Sub
    ErrHandler:
        MsgBox "An unforeseen problem has occurred. Please contact support."
        Resume Clean_up
    End Sub

如果您的例程中始终包含该代码，则可以将其移至您从 Clean_up 部分调用的单独例程中。

Answer 2

一种简化的方法是使用 RAII 模式：即编写一个在其 Class_Terminate 事件过程中进行清理的类。例如，您可以创建包含以下内容的类模块“CursorSaver”：

Private m_SavedCursor As XlMousePointer
Private m_SavedScreenUpdating As Boolean

Private Sub Class_Initialize()
    m_SavedCursor = Application.Cursor
    m_SavedScreenUpdating = Application.ScreenUpdating
End Sub

Private Sub Class_Terminate()
    Application.Cursor = m_SavedCursor
    Application.ScreenUpdating = m_SavedScreenUpdating
End Sub

然后你可以在你的子函数和函数的开始处创建这个类的一个实例，当函数退出时，这个类实例会超出作用域并且会自动调用终止代码并恢复初始状态：

Public Sub MySub
    Dim saver As New CursorSaver
    ...
    Exit Sub
End Sub ' Cursor and ScreenUpdating are automatically restored when the Sub exits

This answer to another question 包含一个类似的例子。

Answer 3

我还发现自己在我的程序中反复添加类似的错误处理代码，至少可以说有点乏味。有一个名为 MZTools 的 VBIDE 插件能够添加代码 sn-ps，您可以轻松地将其嵌入代码中，包括错误处理程序。 sn-ps 允许包含占位符，例如过程名称，因此它可以适应目标过程。早期版本是免费的，但 v8 确实要花钱，而且我认为它有点贵，但它还有很多其他功能，它是你的选择。

这是一个示例错误处理程序，您可以查看占位符的工作原理

Dim mpSettings As ApplicationSettings
Dim mpTopLevel As Boolean

    Const mpProcedure As String = "{PROCEDURE_NAME}"

    On Error GoTo {PROCEDURE_NAME}_Error
    'can be a top-level call or initiated by another
    mpTopLevel = IIf(IsArrayAllocated(mgVecProcStack), False, True)
    PushProcedureStack mpProcedure, mpTopLevel

    {PROCEDURE_NAME}= True

    Call AppSettings(State:="Set", _
                     AppType:=mpSettings, _
                     AppEvents:=True, _
                     AppScreen:=True, _
                     AppAlerts:=False, _
                     AppCalc:=appNotEnabled)

    {PROCEDURE_BODY}

{PROCEDURE_NAME}_Tidy:
    PopProcedureStack      

{PROCEDURE_NAME}_Tear_Down:               

{PROCEDURE_NAME}_Exit:
    Call AppSettings(State:="Reset", _
                     AppType:=mpSettings, _
                     AppEvents:=True, _
                     AppScreen:=True, _
                     AppAlerts:=False, _
                     AppCalc:=appNotEnabled)
    Exit Function

{PROCEDURE_NAME}_Error:
    If Err.Number = mgBypassErrorNum Then Resume {PROCEDURE_NAME}_Tear_Down
    {PROCEDURE_NAME} = False
    If AppErrorHandler(mmModule, mpProcedure, mpTopLevel) Then
        Stop
        Resume
    Else
        Resume {PROCEDURE_NAME}_Exit
    End If

我与MZTools或作者没有任何关系，它只是我使用并从中获得价值的工具。