为什么 MS Access 提示在更新查询中输入已经有值的参数？

Question

我正在创建一个数据库，用户可以在其中更改表中公司的名称。但是，每当我使用更新查询时，它都会要求提供一个已经提供的参数。旧公司名称在变量new_comp 中，然后新公司名称在Me.comp1_box.Value 中。

有趣的是，只要我点击确定并且在“输入参数”设置中不输入任何内容，查询就会运行得很好

Dim record_changer As String
         
record_changer = "UPDATE " & "[" & new_comp & "]" & " SET " & "[" & new_comp & "]" & ".Company_Name =" & """" & Me.comp1_box.Value & """" & ";"
     
MsgBox (record_changer)
             
DoCmd.RunSQL (record_changer)

这是 record_changer 的最终值。 更新 [EREDEON TECHNOLOGIES] SET [EREDEON TECHNOLOGIES].Company_Name="EREDEON TECH";

代码运行时是这样的。

• This is the query that it is supposed to run
• It gives this prompt meaning it's supposed to run perfectly, meaning there is nothing wrong with the Query
• This what pops up

谁能帮帮我？ 我真的迷路了。旧公司名称是EREDEON TECHNOLOGIES，新名称是EREDEON TECH 但有趣的是，当我没有在参数对话框中输入值就直接点击 Okay 时，它实际上进行了更改。-_- 很奇怪

• This happens, then I press "OK"
• THEN THIS HAPPENS, Then I hit Okay
• This is the table before.
• It updates the table the new value which is EREDEON TECH. When I just hit OK, without typing anything into Parameter Dialogue.

Answer 1

尝试将您的 SQL 字符串更改为以下内容。请注意 Me.comp1_box.Value 周围的 单引号 变化。

record_changer = "UPDATE " & "[" & new_comp & "]" & " SET " & "[" & new_comp & "]" & ".Company_Name ='" & Me.comp1_box.Value & "';"

误用引号是导致参数值提示的最常见原因。如果这不起作用，请使用本文对所有其他常见原因进行分步故障排除，Why does Access want me to enter a parameter value?

您还可以参考以下文章：

MS Docs，Quotation marks in string expressions
字节，(') and (") - Where and When to use them

Answer 2

从根本上说，这个问题是由于在 VBA 中使用了双引号，它本身在 Access SQL 中工作，但不能通过 VBA 使用 DoCmd.RunSQL。您可以使用单引号将公司名称值括起来。

但是，首先要避免将 VBA 文字连接到带有引号的 SQL 查询。相反，请使用 MS Access 中可用的行业最佳参数化实践，在 VBA 中使用 QueryDefs，在 SQL 中使用 PARAMETERS 子句：

Dim record_changer As String
Dim qdef As QueryDef

sql = "PARAMETERS new_name_param TEXT; " _
       & "UPDATE [" & new_comp & "] " _
       & "SET Company_Name = new_name_param;"

' SET UP QUERYDEF
Set qdef = CurrentDb.CreateQueryDef("", sql)

' BIND PARAMS
qdef!new_name_param = Me.comp1_box.Value

' RUN ACTION
qdef.Execute

' RELEASE RESOURCE
Set qdef = Nothing

尽管如此，在查询中需要连接表名new_comp 是有问题的数据库设计。专有名称（EREDEON TECHNOLOGIES、GAME DISCOUNT STORE、SHOPRITE 等）绝不应该是表的名称。避免为每个公司维护单独的表格。相反，对所有公司的单个表的数据进行规范化，然后运行 ​​UPDATE 和 WHERE 添加第二个参数。

' PREPARED STATEMENT, NO VARIABLE CONCATENATION
sql = "PARAMETERS new_name_param TEXT, old_name_param TEXT; " _
      & " UPDATE Companies " _
      & " SET Company_Name = new_name_param" _
      & " WHERE Company_Name = old_name_param;"

Set qdef = CurrentDb.CreateQueryDef("", sql)

qdef!new_name_param = Me.comp1_box.Value
qdef!old_name_param = new_comp

qdef.Execute

事实上，由于上​​面的 SQL 现在已经从 VBA 中分离出来，所以将没有 VBA 标点符号（&、" 或 _）的查询保存为单独的对象，并在 QueryDefs 中按名称调用它：

Set qdef = CurrentDb.QueryDefs("mySavedQuery")

qdef!new_name_param = Me.comp1_box.Value
qdef!old_name_param = new_comp

qdef.Execute

---

更好的是，如果您的参数源自打开表单上的控件，请将它们直接包含在查询中以进行单行 VBA 调用。下面运行单个 Companies 表的规范化版本：

SQL （另存为查询对象，调整名称为实际）

UPDATE Companies
SET Company_Name = Forms!myForm!comp1_box 
WHERE Company_Name = Forms!myForm!new_comp

VBA （无需关闭操作查询）

DoCmd.OpenQuery "mySavedQuery"