删除字符串中的 Unicode 字符

Question

如何删除 VBA 中所有不属于 ASCII 类别的特殊字符？

这些是我的字符串中出现的一些符号。

Œ – Š š Ÿ ƒ

这样的角色还有很多。

这些不属于 ASCII 类别，您可以在此处看到 http://www.ascii.cl/htmlcodes.htm

我试过这样的

strName = Replace(strName, ChrW(376), " ")

Answer 1

不需要循环每个字符

也许迟到了，但也许对某人有帮助：

Public Function StripNonAsciiChars(ByVal InputString As String) As String
    Dim i As Integer
    Dim RegEx As Object
    Set RegEx = CreateObject("VBScript.RegExp")
    With RegEx
        .Global = True
        .MultiLine = True
        .IgnoreCase = True
        .Pattern = "[^\u0000-\u007F]"
        StripNonAsciiChars = Application.WorksheetFunction.Trim(RegEx.Replace(InputString, " "))
    End With
End Function

Answer 2

您会对RegEx 解决方案感兴趣吗？

这个网站上有很多不同语言的示例 - 这是一个 C# 示例：How can you strip non-ASCII characters from a string? (in C#)。

为 VBA 试试这个：

Private Function GetStrippedText(txt As String) As String
    Dim regEx As Object

    Set regEx = CreateObject("vbscript.regexp")
    regEx.Pattern = "[^\u0000-\u007F]"
    GetStrippedText = regEx.Replace(txt, "")

End Function

Answer 3

下面试试

Function ClearUnwantedString(fulltext As String) As String
    Dim output As String
    Dim character As String
    For i = 1 To Len(fulltext)
        character = Mid(fulltext, i, 1)
        If (character >= "a" And character <= "z") Or (character >= "0" And character <= "9") Or (character >= "A" And character <= "Z") Then
            output = output & character
        End If
    Next
    ClearUnwantedString = output
End Function

Sub test()
    a = ClearUnwantedString("dfjŒœŠdskl")
End Sub

Answer 4

假设你有：

那么下面的代码将从A1 中获取String，并且只让A2 中的ANSI（代码0 到255）通过。

Sub test()
 Dim s1 As String, s2 As String, c As String, i As Long, iAsc As Integer

 s1 = Range("A1").Value

 s2 = ""

 For i = 1 To Len(s1)
  c = Mid(s1, i, 1)
  iAsc = AscW(c)
  If iAsc <= 255 Then
   s2 = s2 & c
  End If
 Next

 Range("A2").Value = s2

End Sub

Answer 5

当您在即时窗口中写下以下内容时，您会得到什么？

?Replace("ŸŸŸŸ", ChrW(376), "ale")

我得到： 栀子花

Answer 6

试试application.clean()

它将删除所有不可打印的字符