单元格区域中的应用程序定义或对象定义的错误visual basic答案

【问题标题】：application-defined or object-defined error in cell range visual basic单元格区域中的应用程序定义或对象定义的错误visual basic
【发布时间】：2013-05-09 04:38:14
【问题描述】：

下面的代码有一些问题。我在启动第二个 for 循环时遇到应用程序定义或对象定义的错误。第二个循环范围的格式似乎是导致问题的原因。删除 Sheets() 对象可以消除错误，但随后脚本会从错误的工作表中读取，并且不会返回任何数据。

此代码的目标是遍历垂直的数据数组，然后如果找到与下拉列表中的选择匹配的内容，它会遍历水平的数据数组并返回颜色变化，如果它找到一个 '是的价值。

If Not Intersect(Target, Range("countryProductCell")) Is Nothing Then
    lastcolumn = ActiveSheet.UsedRange.Column - 1 + ActiveSheet.UsedRange.Columns.Count
    Dim cellRow As Integer
    cellRow = Target.Row
    Dim defaultCellColumn As Integer
    defaultCellColumn = 4
    i = 5
    j = 1
    k = 1
    If Not Cells(cellRow, defaultCellColumn).Value = "(Select Title)" Then
        For Each countryCell In Range(Cells(cellRow, defaultCellColumn + 1), Cells(cellRow, lastcolumn))
            If countryCell.Value = "Use Default" Then
                countryCell.Interior.ColorIndex = 3
            End If
        Next
        For Each nameCell In Sheets("Active Product Catalog").Range("ProductNames")
            If nameCell.Value = Cells(cellRow, defaultCellColumn).Value Then
                'Error on the line below!
                For Each purchaseableCell In Sheets("Active Product Catalog").Range(Cells(nameCell.Row, 10), Cells(nameCell.Row, 27))
                    If purchaseableCell.Value = "Yes" Then
                        'If Purchaseable, Change Color
                        Sheets("Home Template").Cells(cellRow, defaultCellColumn + j).Interior.ColorIndex = 35
                    End If
                    j = j + 1
                Next
            End If
            k = k + 1
        Next
    ElseIf Cells(cellRow, defaultCellColumn).Value = "(Select Title)" Then
        If Target.Value = "(Select Title)" Then
            Target.Interior.Color = Cells(Target.Row, Target.Column - 1).Interior.Color
            For Each countryCell In Range(Cells(cellRow, defaultCellColumn + 1), Cells(cellRow, lastcolumn))
                If countryCell.Value = "Use Default" Then
                    countryCell.Interior.ColorIndex = 2
                End If
                i = i + 1
            Next
        ElseIf Target.Value = "Use Default" Then
            Target.Interior.ColorIndex = 2
        ElseIf Application.VLookup(ActiveSheet.Cells(cellRow, Target.Column), Sheets("Active Product Catalog").Range("E:AK"), Target.Column, False) = "Yes" Then
            Target.Interior.ColorIndex = 35
        ElseIf Not Application.VLookup(ActiveSheet.Cells(cellRow, Target.Column), Sheets("Active Product Catalog").Range("E:AK"), Target.Column, False) = "Yes" Then
            Target.Interior.ColorIndex = 3
        End If
    End If
End If

【问题讨论】：

@steveo40 所说的，但更广泛地说，不要在没有包含合格工作表参考的情况下使用 Range() 或 Cells()：否则你总是依赖于当前活动表的内容：this使您的代码容易出现难以追踪的错误。

标签： object excel for-loop excel-2010 vba

【解决方案1】：

您需要限定代码中的单元格引用。它失败的原因是您正在使用一个工作表（活动工作表）中的两个单元格引用并要求 VBA 在另一个工作表（活动产品目录）中定义一个范围。试试这样的：

Sheets("Active Product Catalog").Range(Sheets("Active Product Catalog").Cells(nameCell.Row, 10), Sheets("Active Product Catalog").Cells(nameCell.Row, 27))

如果您创建工作表对象或使用 With 语句，您可能会发现它更易于阅读。

【讨论】：