为什么我的循环没有遍历所有值？

Question

我正在尝试让 Excel vba 宏工作。我使用的代码如下：

Dim foo, bar, toto As Double
Dim nb As Integer
nb = 1

For bar = 1 To 1 Step 0.2
For toto = 1 To 4 Step 0.2
For foo = 1 To 2 Step 0.2
    Cells(nb, 1).Value = CStr("bar " & bar & " toto " & toto & " foo " & foo)
    nb = nb + 1
Next foo
Next toto
Next bar
End Sub

我希望看到 toto=4 的案例被打印出来。我得到的最终结果是：

bar 1 toto 1 foo 1
bar 1 toto 1 foo 1.2
bar 1 toto 1 foo 1.4
[....]
bar 1 toto 3.8 foo 1.6
bar 1 toto 3.8 foo 1.8
bar 1 toto 3.8 foo 2

变量 foo 按预期从 1 变为 2，并且每次递增 0.2。 另一方面，变量 toto 从 1 变为 3.8，而不是上升到 4。

如何更改我的代码以使 toto 达到 4 ？ 我尝试将我的 for 循环的上限值更改为 (max + 1 step)，并且 for toto 它工作但对于 foo 和 bar 它们是一个“额外”循环。

我尝试将代码更改为基于一段时间的方法，但也没有成功。

bar = 1
toto = 1
foo = 1
nb = 1

While (bar <= 1)
toto = 1
    While (toto <= 4)
    foo = 1
        While (foo <= 2)
        
        Cells(nb, 4).Value = CStr("bar " & bar & " toto " & toto & " foo " & foo)
        nb = nb + 1
        foo = foo + 0.2
        Wend
    toto = toto + 0.2
    Wend
bar = bar + 0.2
Wend

Answer 1

这是由于浮点错误。我会避免使用Step 0.2，而是在循环内将foo、bar 和toto 乘以0.2，同时在循环时只使用整数：

Dim foo As Long, bar As Long, toto As Long, nb As Long

nb = 1

For bar = 1 To 5
    For toto = 1 To 20
        For foo = 1 To 10
            Cells(nb, 1).Value = CStr("bar " & bar * 0.2 & " toto " & toto * 0.2 & " foo " & foo * 0.2)
            nb = nb + 1
        Next
    Next
Next

另请注意，在vba 中，Dim foo, bar, toto As Double 仅将toto 声明为Double。 foo 和 bar 是 Variants。

Answer 2

您错误地声明了变量。您需要在每个声明中添加 As 声明。你这样做的方式使foo 和bar 的类型为Variant，这可能是VBA 当时想要的任何东西。最好每行有一个声明。如果我们让鞋面稍微大于 4，比如 4.01，那么它就可以工作。我不知道为什么。

Dim foo As Double
Dim bar As Double 
Dim toto As Double
Dim nb As Integer
nb = 1

For bar = 1 To 1 Step 0.2
    For toto = 1 To 4.01 Step 0.2
        For foo = 1 To 2 Step 0.2
            Cells(nb, 1).Value = CStr("bar " & bar & " toto " & toto & " foo " & foo)
            nb = nb + 1
        Next foo
    Next toto
Next bar

如果您不喜欢在toto 的上限上添加一些斜率，您也可以使用Round 强制有效数字。

这个按你预期的方式工作：

Sub test()
    Dim foo As Single
    Dim bar As Single
    Dim toto As Single
    Dim nb As Integer
    nb = 1
    
    For bar = 1 To 1 Step 0.2
        For toto = 1 To 4 Step 0.2
            toto = Round(toto, 1)
            For foo = 1 To 2 Step 0.2
                Debug.Print CStr("bar " & bar & " toto " & toto & " foo " & foo)
                nb = nb + 1
            Next foo
        Next toto
    Next bar
End Sub