如何使用 For-Loop 重复 VBA 代码

Question

我需要帮助为 H 列中的每个 ID 执行第一个代码。我尝试建立一个“循环”和一个“for next”，但无济于事。

我想建立一个“i = 行号”类型并有一个“i + 1”命令，它将对列中的每个单元格执行相同的任务

真诚感谢任何帮助！

Sub GenerateAll_1()

'Copy the first ID in the list (cell H2) and paste it
    Sheets("Specialist Roster").Select
    Range("H2").Select
    Selection.Copy
    Sheets("Weekly Productivity").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
'My code that saves as pdf based on other criteria goes here

'REPEAT task for the cells H3, H4... H260

Answer 1

这个示例实际上只是为了让您了解 for 循环在此处如何工作。应该注意的是，循环不是在工作表之间复制和粘贴值的最有效方式。我认为其他一些解决方案可以更好地解决有效的方法：

For i = 2 To 260
Sheets("Specialist Roster").Range("H" & i).Copy
'here you need to specify what range you want to copy to
Sheets("Weekly Productivity").Range("H" & i).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
 Next i

这不是一个很好的缩放解决方案，因为它被硬编码为执行第 2 行到第 260 行。但是使用一些变量可以做得更好。希望这有点帮助...

Answer 2

这是一个单行子：

Sub GenerateAll_1()
    Sheets("Specialist Roster").Range("H2:H" & Rows.Count).Copy Sheets("Weekly Productivity").Range("H2")
End Sub

不需要循环。如果您想避免第 260 行下方 H 列中的值，则：

Sub GenerateAll_1()
    Dim r1 As Range, r2 As Range

    Set r1 = Sheets("Specialist Roster").Range("H2:H260")
    Set r2 = Sheets("Weekly Productivity").Range("H2")

    r1.Copy r2
End Sub

Answer 3

如您的代码所示 (xlPasteValues)，仅复制数据，请执行以下操作：

Sheets("Weekly Productivity").Range("H2:H260") = 
    Sheets("Specialist Roster").Range("H2:H260").Value

没有循环。

你甚至可以不用代码，只需在“每周生产力”中输入一个公式：

在单元格 H2 中：

='Specialist Roster'!H2

...并根据需要向下拖动。

如果你真的需要循环（因为你想根据中间结果执行其他任务），那么就这样做吧：

Sub GenerateAll_1()
    Dim source As Range ' cell from which you copy
    Dim target As Range ' cell to which you copy

    Set target = Sheets("Weekly Productivity").Range("H1")

    For Each source In Sheets("Specialist Roster").Range("H2:H260")
        target = source.Value ' copy the value (only)
        Set target = target.Offset(1) ' let target point to next cell
        ' perform other tasks here
    Next

End Sub