F# 中 seq<int> 与 Lazy<LazyList<int>> 的性能

Question

有一个众所周知的解决方案可以生成无限的汉明数流（即所有正整数n，其中n = 2^i * 3^j * 5^k）。我在 F# 中以两种不同的方式实现了这一点。第一种方法使用seq<int>。解决方案很优雅，但性能很糟糕。第二种方法使用自定义类型，其中尾部包裹在Lazy<LazyList<int>> 中。解决方案笨拙，但性能惊人。

有人可以解释为什么使用seq<int> 的性能如此糟糕，是否有办法解决它？谢谢。

方法一使用seq<int>。

// 2-way merge with deduplication
let rec (-|-) (xs: seq<int>) (ys: seq<int>) =
    let x = Seq.head xs
    let y = Seq.head ys
    let xstl = Seq.skip 1 xs
    let ystl = Seq.skip 1 ys
    if x < y then seq { yield x; yield! xstl -|- ys }
    elif x > y then seq { yield y; yield! xs -|- ystl }
    else seq { yield x; yield! xstl -|- ystl }

let rec hamming: seq<int> = seq {
    yield 1
    let xs = Seq.map ((*) 2) hamming
    let ys = Seq.map ((*) 3) hamming
    let zs = Seq.map ((*) 5) hamming
    yield! xs -|- ys -|- zs
}

[<EntryPoint>]
let main argv = 
    Seq.iter (printf "%d, ") <| Seq.take 100 hamming
    0

使用Lazy<LazyList<int>>的方法2。

type LazyList<'a> = Cons of 'a * Lazy<LazyList<'a>>

// Map `f` over an infinite lazy list
let rec inf_map f (Cons(x, g)) = Cons(f x, lazy(inf_map f (g.Force())))

// 2-way merge with deduplication
let rec (-|-) (Cons(x, f) as xs) (Cons(y, g) as ys) =
    if x < y then Cons(x, lazy(f.Force() -|- ys))
    elif x > y then Cons(y, lazy(xs -|- g.Force()))
    else Cons(x, lazy(f.Force() -|- g.Force()))

let rec hamming =
    Cons(1, lazy(let xs = inf_map ((*) 2) hamming
                 let ys = inf_map ((*) 3) hamming
                 let zs = inf_map ((*) 5) hamming
                 xs -|- ys -|- zs))

[<EntryPoint>]
let main args =
    let a = ref hamming
    let i = ref 0
    while !i < 100 do
        match !a with
        | Cons (x, f) ->
            printf "%d, " x
            a := f.Force()
            i := !i + 1
    0

Answer 1

Ganesh 是正确的，因为您正在多次评估序列。 Seq.cache 将有助于提高性能，但您可以从 LazyList 获得更好的性能，因为底层序列只评估一次然后缓存，因此可以更快地遍历它。事实上，这是一个很好的例子，说明LazyList 应该 用于普通的seq。

您在此处使用Seq.map 似乎也引入了一些重大开销。我相信编译器在每次调用时都会分配一个闭包。我将您的基于seq 的代码更改为在那里使用seq-表达式，对于序列中的前40 个数字，它比原始代码快约1/3：

let rec hamming: seq<int> = seq {
    yield 1
    let xs = seq { for x in hamming do yield x * 2 }
    let ys = seq { for x in hamming do yield x * 3 }
    let zs = seq { for x in hamming do yield x * 5 }
    yield! xs -|- ys -|- zs
}

我的ExtCore 库包含一个lazyList 计算构建器，其工作方式与seq 类似，因此您可以像这样简化代码：

// 2-way merge with deduplication
let rec (-|-) (xs: LazyList<'T>) (ys: LazyList<'T>) =
    let x = LazyList.head xs
    let y = LazyList.head ys
    let xstl = LazyList.skip 1 xs
    let ystl = LazyList.skip 1 ys
    if x < y then lazyList { yield x; yield! xstl -|- ys }
    elif x > y then lazyList { yield y; yield! xs -|- ystl }
    else lazyList { yield x; yield! xstl -|- ystl }

let rec hamming : LazyList<uint64> = lazyList {
    yield 1UL
    let xs = LazyList.map ((*) 2UL) hamming
    let ys = LazyList.map ((*) 3UL) hamming
    let zs = LazyList.map ((*) 5UL) hamming
    yield! xs -|- ys -|- zs
}

[<EntryPoint>]
let main argv =
    let watch = Stopwatch.StartNew ()

    hamming
    |> LazyList.take 2000
    |> LazyList.iter (printf "%d, ")

    watch.Stop ()
    printfn ""
    printfn "Elapsed time: %.4fms" watch.Elapsed.TotalMilliseconds

    System.Console.ReadKey () |> ignore
    0   // Return an integer exit code

（注意：我还使您的 (-|-) 函数通用，并修改 hamming 以使用 64 位无符号整数，因为 32 位有符号整数稍后会溢出）。这段代码在我的机器上运行序列的前 2000 个元素，大约 450 毫秒；前 10000 个元素大约需要 3500 毫秒。

Answer 2

您的seq 用于hamming 会在每次递归调用时从头开始重新评估。 Seq.cache 有帮助：

let rec hamming: seq<int> =
    seq {
        yield 1
        let xs = Seq.map ((*) 2) hamming
        let ys = Seq.map ((*) 3) hamming
        let zs = Seq.map ((*) 5) hamming
        yield! xs -|- ys -|- zs
    } |> Seq.cache

但是，正如您指出的那样，LazyList 在大输入上仍然要好得多，即使每个序列都被缓存。

我不完全确定为什么它们的差异不仅仅是一个小的常数因素，但也许最好只专注于使 LazyList 不那么难看。编写一些内容将其转换为 seq 可以更好地处理它：

module LazyList =
    let rec toSeq l =
        match l with
        | Cons (x, xs) ->
            seq {
                yield x
                yield! toSeq xs.Value
            }

然后您可以直接使用您的简单main。也没有必要使用突变来处理LazyList，你可以递归地这样做。

虽然lazy 和Force() 确实有点混乱，但定义看起来并不那么糟糕。如果您使用.Value 而不是.Force()，那看起来会稍微好一些。您还可以为LazyList 定义一个computation builder，类似于seq 来恢复非常好的语法，尽管我不确定这是否值得。

Answer 3

这是一个性能更好的序列基础版本。

let hamming =
    let rec loop nextHs =
        seq {
            let h = nextHs |> Set.minElement
            yield h
            yield! nextHs 
                |> Set.remove h 
                |> Set.add (h*2) |> Set.add (h*3) |> Set.add (h*5) 
                |> loop
            }

    Set.empty<int> |> Set.add 1 |> loop