Excel：如何为不同的人提供不同级别的保护和访问权限

Question

我有一个 3 种不同类型的人可以访问的 Excel 电子表格，我希望这 3 种类型的人具有不同的访问权限。我希望有完全访问权限的人，所以可以更改工作簿、更改单元格、更改单元格的内容和格式等。有一些访问权限的人，所以只能更改一些单元格并且可以继续任何访问电子表格时可见的工作表，我希望有人访问受限，因此只能在某些工作表上进行，更改检索与该值关联的数据所需的单元格，并且无法保存文件.

有没有办法做到这一点？

我真正想要的是当文件打开时要求用户输入密码，并且根据密码是什么，不同的单元格被锁定并应用不同的访问级别。

Answer 1

首先将命名范围分配给您要保护的区域，使用后缀指示如何处理它们。您可以通过选择范围并在公式栏左侧键入一个不是有效单元格地址的名称来做到这一点。

我创建了名为 Someting_4U 的范围，你和我可以编辑它和Something_4Me，只有我可以编辑

现在复制以下代码到主ThisWorkbook模块

Private Sub Workbook_Open()
    Dim Sht As Worksheet, Nm As Name

'取消保护您的工作簿和工作表

    ThisWorkbook.Unprotect "onlyVbaPassWord"
    For Each Sht In ThisWorkbook.Sheets
        Sht.Unprotect "onlyVbaPassWord"
    Next Sht

' 取消保护适当的命名范围并保护其他范围

    For Each Nm In ThisWorkbook.Names

        ' The next `Select Case` statement implements your business logic
        Select Case Application.UserName
            Case "Me", "Myself", "I"
                Nm.RefersToRange.Locked = False
            Case "You", "Yourself", "Thou"
                If Nm.Name Like "*_4U" Then
                    Nm.RefersToRange.Locked = False
                Else
                    Nm.RefersToRange.Locked = True
                End If
            Case Else
                Nm.RefersToRange.Locked = True
        End Select
    Next Nm

'再次保护您的工作表和工作簿

    For Each Sht In ThisWorkbook.Sheets
        Sht.Protect "onlyVbaPassWord"
    Next Sht
    ThisWorkbook.Protect "onlyVbaPassWord"
End Sub