在jq中，如何让tonumber输出十进制而不是科学计数法

Question

在 JSON 对象中，给定字符串 "0.0000086900" 作为键值对的值，如果我对此执行 |tonumber，则返回 8.69e-06。

如何确保只返回小数？ 在上述情况下，这将是 0.0000086900

解决方案（基于以下 Peak 的代码 sn-p）

def to_decimal:
  def rpad(n): if (n > length) then . + ((n - length) * "0") else . end;
  def lpad(n): if (n > length) then ((n - length) * "0") + . else . end;

tostring
  | . as $s
  | [match( "(?<sgn>[+-]?)(?<left>[0-9]*)(?<p>\\.?)(?<right>[0-9]*)(?<e>[Ee]?)(?<exp>[+-]?[0-9]+)" )
      .captures[].string] as [$sgn, $left, $p, $right, $e, $exp]
  | if $e == "" then .
    else ($exp|tonumber) as $exp
    | ($left|length) as $len
    | if $exp < 0 then "0." + ($left | lpad(1 - $exp - $len)) + $right
      else ($left | rpad($exp - $len)) + "." + $right
      end
      | $sgn + .
    end;

Answer 1

不幸的是，目前 jq 中没有办法像这样修改 JSON 数字的表示；最好的办法是将它们的表示修改为字符串。这是可以做什么的简单说明。

to_decimal 将 JSON 数字（或数字的有效 JSON 字符串表示形式，可能带有前导“+”）作为输入，并将其转换为合适的字符串，例如：

["0","1","-1","123","-123",".00000123","1230000","-.00000123","-0.123","0.123","0.001"]

产生：

[0,"0"]
["+1","1"]
[-1,"-1"]
[123,"123"]
[-123,"-123"]
[1.23e-06,".00000123"]
[1230000,"1230000"]
[-1.23e-06,"-.00000123"]
[-0.123,"-0.123"]
[0.123,"0.123"]
[0.001,"0.001"]

请注意，任何前导的“+”都会被删除。

to_decimal

def to_decimal:
  def rpad(n): if (n > length) then . + ((n - length) * "0") else . end;
  def lpad(n): if (n > length) then ((n - length) * "0") + . else . end;

  tostring
  | . as $s
  | capture( "(?<sgn>[+-]?)(?<left>[0-9]*)(?<p>\\.?)(?<right>[0-9]*)(?<e>[Ee]?)(?<exp>[+-]?[0-9]+)" )
  | if .e == "" then (if .sgn == "+" then $s[1:] else $s end)
    else (.left|length) as $len
    | (.exp|tonumber) as $exp
    | (if .sgn == "-" then "-" else "" end ) as $sgn
    | if $exp < 0 then "." + (.left | lpad(1 - $exp - $len)) + .right
      else (.left | rpad($exp - $len)) + "." + .right
      end
      | $sgn + .
    end ;