SQL Server - 在链中查找不属于任何人的字母

Question

我有一个查询，它使用 itemnum 并搜索表以找到链中没有任何 replacementItemNum 的 itemnum。

就像一条链，a属于b，b属于c，需要在链中找到不属于任何人的字母。

表有 72k 条记录。

• 如果我通过 A 或 B 或 C，我会得到字母 D，因为它没有任何替换项。

• 如果我通过 D，那么结果将为 NULL

这是数据（链）的样子：

ItemNum - ReplacementItemNum
----------------------------    
    A     -  B
    B     -  C
    C     -  D
    D     -  

此查询耗时过长；可以重写一下，这样就不用那么长时间了？

DECLARE @CountryOID INT = 250 ,
        @ItemNum VARCHAR(50) = 'A';

DECLARE @LastItem VARCHAR(50);
DECLARE @NextItem VARCHAR(50);

SELECT @LastItem = ReplaceItemNum
FROM dbo.MacInventory
WHERE ItemNum = @ItemNum
  AND CountryOID = @CountryOID;

WHILE @LastItem <> ''
BEGIN
    SET @NextItem = @LastItem;

    SELECT @LastItem = ReplaceItemNum
    FROM dbo.MacInventory
    WHERE ItemNum = @LastItem
      AND CountryOID = @CountryOID;
END;

SELECT @NextItem; 

Answer 1

Recursive cte 来救援！

首先，创建并填充示例表（请在您以后的问题中保存我们这一步）：

DECLARE @T AS TABLE
(
    ItemNum char(1),
    ReplacementItemNum char(1)
);

INSERT INTO @T (ItemNum, ReplacementItemNum) VALUES
('A', 'B'), 
('B', 'C'),
('C', 'D'),
('D', NULL),
('E', 'F'), -- added some more data to make sure we don't get the wrong result...
('F', NULL);

设定起点：

DECLARE @StartFrom char(1) = 'A';

递归cte：

WITH CTE AS
(
    SELECT ItemNum, ReplacementItemNum
    FROM @T
    WHERE ItemNum = @StartFrom

    UNION ALL

    SELECT T.ItemNum, T.ReplacementItemNum
    FROM @T As T
    JOIN CTE 
        ON T.ItemNum = CTE.ReplacementItemNum
)

查询：

SELECT IIF(ItemNum = @StartFrom, NULL, ItemNum) As ItemNum
FROM CTE
WHERE ReplacementItemNum IS NULL

最后，结果：

ItemNum
D

You can see a live demo on rextester.

Answer 2

您对表中的列 (CountryOID, ItemNum) 是否有适当的索引？尝试以下递归 cte 解决方案：

;WITH cte_item (ItemNum, ReplaceItemNum)
AS
(
SELECT ItemNum, ReplaceItemNum
FROM dbo.MacInventory
WHERE   ItemNum = @ItemNum
AND CountryOID = @CountryOID
UNION
SELECT m.ItemNum, m.ReplaceItemNum
FROM dbo.MacInventory m
INNER JOIN cte_item i
ON m.ItemNum = i.ReplaceItemNum 
AND m.CountryOID = @CountryOID
)
SELECT * FROM cte_item WHERE ReplaceItemNum='';