Excel 2007 真阳性公式答案

【问题标题】：Excel 2007 Formula for True PositiveExcel 2007 真阳性公式
【发布时间】：2014-11-25 15:32:45
【问题描述】：

在 Excel 2007 中，我想根据一些标准计算真阳性、真阴性、假阳性、假阴性结果。例如，如果两个单元格 K10 和 L10 分别包含字符串 True 和 True，则将显示结果“True Positive”，如果 False 和 False =“True Negative”等。这是公式，但它显示#VALUE。提前感谢您的帮助

=IF(ISNUMBER(SEARCH("TRUE";K10&"TRUE";L10));"True Positive";"False Positive");IF(ISNUMBER(SEARCH("FALSE";K10&"FALSE";L10));"True Negative";"False Negative")

【问题讨论】：

L10 我有另一个返回 TRUE 或 FALSE 的公式，所以我相信它会像“这经常是真的”。

标签： excel excel-formula

【解决方案1】：

一个单元格中有 2 个 if 语句，这是不允许的。另外，您不需要使用IsNumber(Search())，您可以使用AND() 并使用等效操作来查看单元格是TRUE 还是FALSE

要正确执行此操作，您需要像这样嵌套 if 语句：

=IF(AND(K10=TRUE,L10=TRUE),"True Positive",IF(AND(K10=TRUE,L10=FALSE),"False Positive",IF(AND(K10=FALSE,L10=TRUE),"False Negative",IF(AND(K10=FALSE,L10=FALSE),"True Negative"))))

这是真值表。

【讨论】：

非常感谢您的快速响应。所以不能只在一个单元格中执行此操作吗？
会，但需要更多信息。假设一个是真的，另一个是假的。输出会是什么？假阳性还是假阴性？
如果我们假设一个为真，另一个为假，则输出为假阳性。如果两者均为真，则输出为真阳性。
所以它永远不会是假阴性？
我已经更新了我原来的答案。如果正确，请标记为答案。

【解决方案2】：

结果与接受的答案不同，但基于“一个为真，另一个为假，输出将是假阳性”：

=CHOOSE(1+K10+L10,"True Negative","False Positive","True Positive")

【讨论】：

对于相同的结果，使用 CHOOSE，您可以尝试：=CHOOSE(BIN2DEC(N(K10)&N(L10))+1,"True Negative","False Negative","False Positive","True Positive")
谢谢。我可能已经发布了一个答案，但一个已经被接受了。

【解决方案3】：

此公式提供与 Bijan 相同的结果，并且可以根据所需结果轻松更改以解释 TRUE FALSE 的任何组合。

=CHOOSE(BIN2DEC(N(K10)&N(L10))+1,"True Negative","False Negative","False Positive","True Positive")

它利用了 TRUE 和 FALSE 在强制转换为数值时计算为 1 和 0 的事实。

根据 K10，结果给出 True ... 或 False ... 的输出； ... 正或 ...负取决于 L10 是否与 K10 一致

【讨论】：

【解决方案4】：

我希望这对你有用：

=IF(AND(ISNUMBER(SEARCH(K10,"TRUE")),ISNUMBER(SEARCH(L10,"TRUE"))),"True Positive",IF(AND(ISNUMBER(SEARCH(K10,"TRUE")),ISNUMBER(SEARCH(L10,"FALSE"))),"False Positive", IF(AND(ISNUMBER(SEARCH(K10,"FALSE")),ISNUMBER(SEARCH(L10,"FALSE"))),"True Negative", IF(AND(ISNUMBER(SEARCH(K10,"FALSE")),ISNUMBER(SEARCH(L10,"TRUE"))),"False Negative"))))

【讨论】：

您不需要 IsNumber(Search())。你可以做AND(K10=TRUE,L10=TRUE)
是的，我在发帖后意识到了这一点。谢谢:)