我正在尝试在 VBA 中使用索引和匹配

Question

我对 vba 很陌生，对于我在下面的代码中犯的（许多）错误，我深表歉意。当我设置 x 和 y 变量时出现错误，而且当我尝试运行索引和匹配组合时也出现错误。任何帮助将不胜感激！

Public Sub indexandmatch()

Dim x As Range
Dim y As Range
Dim mycells As Range
Dim p As Variant

'workbooks(1) is the master workbook where I am trying to get the information from the other reports to be entered in to

Application.Workbooks(1).Activate

x = Application.Workbooks(2).Worksheets(1).Range("H:H")
y = Application.Workbooks(2).Worksheets(1).Range("I:I")

'range v is where I would like the values to be entered in the master

For Each mycells In Range("V:V")    
  p = Application.WorksheetFunction.Index(x, Application.WorksheetFunction.Match(mycells.Offset(0, -11).Value, y), 0)
  mycells = p.Value
Next

End Sub

Answer 1

你必须 Set 任何对象变量，因为 range 是

然后使用Application对象函数将可能的错误包装为返回值，以便您可以使用IsError()函数检查它并进行相应的处理

最终避免Select/Activate 模式并使用完全限定的范围引用

Public Sub indexandmatch()
    Dim x As Range
    Dim y As Range
    Dim mycells As Range
    Dim p As Variant

    'workbooks(1) is the master workbook where I am trying to get the information from the other reports to be entered in to

    Set x = Workbooks(2).Worksheets(1).Range("H:H")
    Set y = Workbooks(2).Worksheets(1).Range("I:I")

    'range v is where I would like the values to be entered in the master

    For Each mycells In Workbooks(1).Worksheets("myMasterWorksheetName").Range("V:V") '<--| use fully qualified (up to worksheet and workbook) range reference. (change "myMasterWorksheetName" to you actual master workbook relevant worksheet name
        p = Application.Match(mycells.Offset(0, -11).Value, y)
        If Not IsError(p) Then
            p = WorksheetFunction.Index(x, p, 0)
            If Not IsError(p) Then mycells = p
        End If
    Next
End Sub