Excel 工作表索引

Question

我的以下代码效果很好，但我正在尝试对其进行修改，以便与其用新索引替换索引页面的第 1 列，我宁愿在单元格C11 中开始范围。现在，新索引从索引表的单元格A1 开始。

代码如下：

Private Sub Worksheet_Activate()
Dim wSheet As Worksheet
Dim l As Long

l = 1

    With Me
        .Columns(1).ClearContents
        .Cells(1, 1) = "INDEX"
        .Cells(1, 1).Name = "Index"
    End With

以上是我希望在 C11 及以下单元格中显示的内容...

    For Each wSheet In Worksheets
    If wSheet.Name <> Me.Name Then
        l = l + 1
            With wSheet
                .Range("A1").Name = "Start_" & wSheet.Index
                .Hyperlinks.Add Anchor:=.Range("A1"), Address:="", _
                SubAddress:="Index", TextToDisplay:="Back to Index"
            End With

            Me.Hyperlinks.Add Anchor:=Me.Cells(l, 1), Address:="", _
            SubAddress:="Start_" & wSheet.Index, TextToDisplay:=wSheet.Name
    End If
    Next wSheet

End Sub

我已经成功地修改了代码，以便返回到每张工作表上索引的链接在单元格A4 中没有问题，但我不知道如何从单元格C11 开始替换索引

Answer 1

Cells(1, 1) 指 A1，Cells(11, 3) 指 C11。

Answer 2

也许是这样的..

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim wSheet As Worksheet
Dim l As Long

    With Me
        .Columns(3).ClearContents
        .Cells(10, 3) = "INDEX"
        .Cells(10, 3).Name = "Index"
    End With
'The above is what I want to have show up in cell C11 and below...

    l = 10
    For Each wSheet In Worksheets
    If wSheet.Name <> Me.Name Then
        l = l + 1
            With wSheet
                .Range("A1").Name = "Start_" & wSheet.Index
                .Hyperlinks.Add Anchor:=.Range("A1"), Address:="", _
                SubAddress:="Index", TextToDisplay:="Back to Index"
            End With

            Me.Hyperlinks.Add Anchor:=Me.Cells(l, 3), Address:="", _
            SubAddress:="Start_" & wSheet.Index, TextToDisplay:=wSheet.Name
    End If
    Next wSheet
End Sub