谷歌表格根据条件获取特定单元格范围的每日/每周计数总和答案

【问题标题】：Google Sheets Get Sum of Daily/Weekly Counts for a specific range of cells as per condition谷歌表格根据条件获取特定单元格范围的每日/每周计数总和
【发布时间】：2021-09-17 08:03:36
【问题描述】：

我在 Google Sheet 中有一组数据如下图：

Row No.	A	B	C	D
-	Count	Person Name	Date	Status
1	163	ABC	03-07-2021	1. Done
2	26	ABC	03-07-2021	2. In Progress
3	35	ABC	03-07-2021	2. In Progress
4	21	XYZ	03-07-2021	1. Done
5	0	XYZ	03-07-2021	1. Done
6	17	ABC	04-07-2021	1. Done
7	0	ABC	04-07-2021	1. Done
8	267	ABC	04-07-2021	1. Done
9	29	XYZ	04-07-2021	2. In Progress
10	42	XYZ	04-07-2021	1. Done

对于这些数据，我想要一个跟踪器，它显示列中的所有人员以及行中的所有日期（因为我们必须每天添加日期）以及上述数据中每个日期的计数列的总和，并且仅对于标记为“1.完成”的那些。所以我准备了这个跟踪器，下面是根据上面的数据需要的结果：

Row No.	A	B
Date	ABC	XYZ
03-07-2021	163	21
04-07-2021	284	42

我已经通过查询获得了解决方案，感谢这里的人！解决方案 - =QUERY(A:D, "select C,sum(A) where D start with '1' group by C pivot B", 1)

现在，我实际上需要根据每周 5 个工作日内取得的结果对每个人进行每周计数。不知道是否可以将某些内容添加到此查询中，但考虑是否有针对每日和每周计数的相同公式的解决方法。

提前致谢！

【问题讨论】：

标签： google-apps-script google-sheets google-sheets-formula

【解决方案1】：

不确定这是否是您想要的，但这会按人为您提供每周摘要：

=arrayformula(query({A:D,weeknum(C:C,2),weekday(C:C,2)},"select Col5,sum(Col1) where Col4 starts with '1' group by Col5 pivot Col2 label Col5 'Week number' ",1))

这将忽略周末：

=arrayformula(query({A:D,weeknum(C:C,2),weekday(C:C,2)},"select Col5,sum(Col1) where Col6 <=5 and Col4 starts with '1' group by Col5 pivot Col2 label Col5 'Week number' ",1))

如果需要，您可以更改一周的开始时间和工作日：

WEEKNUM

WEEKDAY

【讨论】：

【解决方案2】：

您可以在表格后面附加WEEKNUM(C:C) 并按该列分组以获得每周计数：

=ARRAYFORMULA(QUERY({A:D,IFERROR(WEEKNUM(C:C),"Week Num")}, "select Col5,sum(Col1) where Col4 starts with '1' group by Col5 pivot Col2", 1))

如果只需要周一到周五的数据，可以在查询条件后面追加dayofweek()：

=ARRAYFORMULA(QUERY({A:D,IFERROR(WEEKNUM(C:C),"Week Num")}, "select Col5,sum(Col1) where Col4 starts with '1' and dayofweek(Col3) > 1 and dayofweek(Col3) < 7 group by Col5 pivot Col2", 1))

样本输出：

参考资料：

WEEKNUM()

Google Query Language

【讨论】：