将IO（也许（IO（也许a））减少到IO（也许a）

Question

我有一个使用 HsOpenSsl 的 readPrivateKey 函数读取 Rsa 密钥的函数，不幸的是，我的函数的签名是这个 String -> IO (Maybe (IO Maybe RsaKey))。我需要 PEM 格式和 Cryptonite.RSA 密钥，我编写了函数 mkRsaKey 来从 PEM 格式的字符串中生成它。

代码如下：

import qualified Crypto.PubKey.RSA as Rsa --from cryptonite
import OpenSSL.EVP.PKey -- from HsOpenSSL
import OpenSSL.PEM -- from HsOpenSSL
import OpenSSL.RSA -- from HsOpenSSL
import Prelude

data RsaKey = RsaKey
  { rsaKeyCryptoniteKey :: Rsa.PrivateKey,
    rsaKeyStringRepr :: String
  }
  deriving (Show)

openSslKeyToCryptoniteKey :: RSAKeyPair -> Maybe Rsa.PrivateKey
openSslKeyToCryptoniteKey key = do
  let d = rsaD key
  let p = rsaP key
  let q = rsaQ key
  let mdP = rsaDMP1 key
  let mdQ = rsaDMQ1 key
  let mqinv = rsaIQMP key
  let size = rsaSize key
  let n = rsaN key
  let e = rsaE key
  dP <- mdP
  dQ <- mdQ
  qinv <- mqinv

  let pub = Rsa.PublicKey size n e
  return $ Rsa.PrivateKey pub d p q dP dQ qinv

openSslKeyToRsaKey :: RSAKeyPair -> IO (Maybe RsaKey)
openSslKeyToRsaKey key = do
  stringRepr <- writePublicKey key
  let maybeCryptoKey = openSslKeyToCryptoniteKey key
  return $ do
    cryptoKey <- maybeCryptoKey
    return $ RsaKey cryptoKey stringRepr

mkRsaKey :: String -> IO (Maybe (IO (Maybe RsaKey)))
mkRsaKey privateKey = do
  someOpenSslKey <- readPrivateKey privateKey PwNone
  let openSslKey = toKeyPair someOpenSslKey
  return $ openSslKeyToRsaKey <$> openSslKey

现在你可以看到类型签名在我看来不是最优的我想要IO (Maybe RsaKey)。我怎样才能做到这一点？

编辑：

我确实做到了，但我使用的是unsafePerformIO：

mkRsaKey :: String -> IO (Maybe RsaKey)
mkRsaKey privateKey = do
  someOpenSslKey <- readPrivateKey privateKey PwNone
  return $ do
    openSslKey <- toKeyPair someOpenSslKey
    unsafePerformIO (openSslKeyToRsaKey $ openSslKey)

据我所知，你永远不应该使用unsafePerformIO 没有它有什么方法可以做到这一点吗？

Answer 1

case 的发现很好。这绝对不是你应该使用unsafePerformIO 的地方。这是一种更紧凑的方式，很有趣。

flattenMaybe :: (Monad m) => m (Maybe (m (Maybe a))) -> m (Maybe a)
flattenMaybe m = m >>= fromMaybe (return Nothing)

为了更有趣，像这样扁平化层的能力是 monad 的特性；我们只是在m (Maybe ...) 上使用该功能，也称为MaybeT。所以我们也可以这样写：

flattenMaybe = runMaybeT . join . fmap MaybeT . MaybeT

进行必要的包装/解包以在MaybeT m (MaybeT m a) -> MaybeT m a 使用join。

Answer 2

找到了一种不使用unsafePerformIO 的方法，诀窍是使用仅在Nothing 情况下使用return 函数的case 语句。这是实现：

mkRsaKey :: String -> IO (Maybe RsaKey)
mkRsaKey privateKey = do
  someOpenSslKey <- readPrivateKey privateKey PwNone
  let maybeOpenSslKey = toKeyPair someOpenSslKey
  case maybeOpenSslKey of
    Just key -> openSslKeyToRsaKey key
    Nothing -> return Nothing