Haskell：从输入列表创建列表元组

Question

我正在尝试设置一些功能来帮助我正在进行的当前项目。我是 Haskell 的新手，正在努力实现我想要的功能。

我有一个列表[a]，并希望它输出四个不同列表([b],[b],[b],[b]) 的元组，其中列表[a] 中的每个项目依次放入输出元组中的下一个列表。所以输入列表[a]中的第一个元素进入第一个列表[b]，[a]中的第二个元素进入第二个列表[b]，[a]中的第三个元素进入第三个列表@987654334 @， 等等。 我曾尝试使用 chunksOf 和 splitEvery/splitAt 但无法获得正确的输出。帮助将不胜感激！谢谢！

Answer 1

您每次“旋转”四元组并添加到第一个元素。所以我们可以使用foldr 模式来实现它，如下所示：

toFour :: [a] -> ([a], [a], [a], [a])
toFour = foldr (\a (bs, cs, ds, as) -> (a:as, bs, cs, ds)) ([], [], [], [])

或具有无可辩驳的模式：

toFour :: [a] -> ([a], [a], [a], [a])
toFour = foldr (\a ~(bs, cs, ds, as) -> (a:as, bs, cs, ds)) ([], [], [], [])

所以这里(bs, cs, ds, as)是我们为列表尾部生成的4元组，我们向右“旋转”以构造元组(as, bs, cs, ds)，然后将项目a添加到第一个列表的 4 元组。

对于整数列表，这给了我们：

Prelude> toFour [1..2]
([1],[2],[],[])
Prelude> toFour [1..3]
([1],[2],[3],[])
Prelude> toFour [1..4]
([1],[2],[3],[4])
Prelude> toFour [1..5]
([1,5],[2],[3],[4])
Prelude> toFour [1..6]
([1,5],[2,6],[3],[4])
Prelude> toFour [1..10]
([1,5,9],[2,6,10],[3,7],[4,8])

当我们使用无可辩驳的模式时，这是懒惰的，因此我们可以例如分配无限列表的元素，然后以获取第二项的前 10 个元素为例：

Prelude> (\(_, l, _, _) -> take 10 l) (toFour [1..])
[2,6,10,14,18,22,26,30,34,38]

Answer 2

定义

f n = transpose . chunksOf n
g xs = let [xs1, xs2, xs3, xs4] = f 4 xs in (xs1, xs2, xs3, xs4) 

f 是通用解决方案。这给了

Prelude> g ['a' .. 'z']
("aeimquy","bfjnrvz","cgkosw","dhlptx") 

签名

Prelude> :t g
g :: [a] -> ([a], [a], [a], [a])

和

Prelude> :t f
f :: Int -> [a] -> [[a]]

信息：

• transpose。
• chunksOf。