搜索 excel 列中的所有列并根据文件夹中的文件名检查值以查看是否存在？答案

【问题标题】：Search all columns in an excel column and check value against file name in folder to see if exists?搜索 excel 列中的所有列并根据文件夹中的文件名检查值以查看是否存在？
【发布时间】：2015-09-05 15:17:21
【问题描述】：

我有一个包含 .txt 文件的文件夹：

\\uksh000-file06\SharedAreas\1.0 Hewden Public\NS\Approval

每个文本文件都有一个随机名称，如下所示：

NS123SHS.txt
NSg234eH.txt
NSds3461.txt

大多数文件的文件名（减去扩展名 .txt）都在我的 Excel 工作表的 c 列中。

NS123SHS
NSds3461

我正在尝试扫描 c 列以检查文件名是否在我的文件夹目录中找到，如果是则显示一条消息说找到，否则显示一条消息说没有找到。

到目前为止，我能够弄清楚的是如何扫描我的列以获取我定义的特定值，但是我希望能够扫描整个列，并比较每个值以查看它是否存在于我的文件夹？

有人可以告诉我如何做到这一点吗？谢谢

Private Sub Workbook_Open()

Dim FindString As String
Dim Rng As Range
FindString = "NSds3461"
If Trim(FindString) <> "" Then
    With Sheets("Home").Range("C:C") 'searches all of column A
        Set Rng = .Find(What:=FindString, _
                        After:=.Cells(.Cells.Count), _
                        LookIn:=xlValues, _
                        LookAt:=xlWhole, _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlNext, _
                        MatchCase:=False)
        If Not Rng Is Nothing Then
             MsgBox "found" 'value not found
        Else
            MsgBox "Reference Not Found" 'value not found
        End If
    End With

End If

【问题讨论】：

看看Dir函数。它将允许您在文件夹中搜索具有给定名称的文件。如果要遍历整个列，则需要在Range 上使用For Each 循环而不是Find。

标签： vba excel search directory

【解决方案1】：

在下面的代码中，您必须将 Worksheets(1) 更新为您拥有文件名的工作表索引，并使用您的信息更新 FOLDER_PATH：

\\uksh000-file06\SharedAreas\1.0 Hewden Public\NS\Approval

Option Explicit

Private Sub Workbook_Open()

    Const FOLDER_PATH   As String = "C:\temp\"
    Const FILE_NAME_COL As Long = 3

    Dim fileNames As Variant, ws As Worksheet, i As Long
    Dim fName As String, result As String

    Set ws = Worksheets(1)

    fileNames = ws.UsedRange.Columns(FILE_NAME_COL)

    For i = 2 To UBound(fileNames)

        fName = Trim(fileNames(i, 1))

        If Len(Dir(FOLDER_PATH & fName)) > 0 Then
            fName = fName & vbTab & ": Found" & vbCrLf
        Else
            fName = fName & vbTab & ": Not Found" & vbCrLf
        End If

        result = result & i - 1 & ". " & vbTab & fName
    Next

    MsgBox result, , "Search Result"

End Sub

结果：

希望对你有帮助

【讨论】：