Windows 环境变量值中的引号

Question

我正在尝试在 Windows 批处理文件中实现逻辑“如果%MyBinaryDir% 尚未在系统的开头%PATH%，则将其放在那里；如果它已经在那里，则什么也不做”。

我有这个：

@echo %PATH% | findstr /i /b /c:"%MyBinaryDir%;" > nul || set "PATH=%MyBinaryDir%;%PATH%

这一直很有效，直到我尝试在某人的机器上进行部署，由于某种神秘的原因，%PATH% 变量包含奇数个引号字符。

问题归结为：

@set x="
@echo %x%
@echo %x% | more

第二行打印一个" 字符。第三行被引号字符绊倒，并且根本无法将echo 输出传递到第二个二进制文件（在我的情况下为findstr，但在这个简化的示例中more）。相反，它会逐字打印字符：

" | more

所以我的问题是：

(Y) 如何安全地将 any 任意字符串传送到第二个二进制文件中？

和/或

(X) 有没有一种方法可以有条件地将目录添加到系统路径以避免这种混乱？

Answer 1

使用延迟扩展以安全的方式回显任何可变内容。

setlocal EnableDelayedExpansion
set x="
echo !x!
echo !x! | more
echo !path! | more

为了安全起见，您也可以使用空变量echo(

echo(!path! | more

还有一个关于pretty print/split the path variable的问题

Answer 2

我建议清理 PATH，因为此环境变量中的目录路径不应包含引号。

这是您的任务的示例批处理代码：

@echo off
rem Uncomment the line below for testing with C:\PythonXX
rem already in PATH with an erroneous double quote in PATH.
rem set "PATH=C:\PythonXX;"%PATH%"

echo Path before clean up:
echo.
echo PATH=%PATH%
set "PATH=%PATH:"=%"
echo.
echo Path after clean up:
echo.
echo PATH=%PATH%
if /I "%PATH:~0,12%" NEQ "C:\PythonXX;" set "PATH=C:\PythonXX;%PATH%"
echo.
echo Path modified:
echo.
echo PATH=%PATH%
echo.
pause

请参阅set environment variables with spaces 上的答案以及那里引用的其他答案，为什么即使分配给变量的值本身包含 1 个或多个引号，也应该使用 set "variable=value"。