如何将分隔符设置为 match() 函数中的参数？

Question

awk '{while(match($0,/("[^"]+",|[^,]*,|([^,]+$))/,a)){
     $0=substr($0,RSTART+RLENGTH);b[++x]=a[0]}
     print b[1] b[4];x=0}' file

我想了解 match 子句，并想知道如何使其动态化，以便它可以将分隔符作为参数，而不是将其硬编码为逗号。

我试过了，但是因为我没有这个功能的背景，所以没有用。

awk -v dl '{while(match($0,/("[^"]+"dl|[^,]*dl|([^,]+$))/,a)){
     $0=substr($0,RSTART+RLENGTH);b[++x]=a[0]}
     print b[1] b[4];x=0}' file

输入文件数据：

a,b,c,"d,e,f",  
"a,b",c,d,"e,f",  
p,q,r,"s,u",  

所需的输出（可能是第 4 个字段）：

d,e,f  
e,f  
s,u  

所需的输出（可能是第 5 个字段，因此它应该生成 3 行空白值）：

在这里，分隔符可以是任何逗号、管道和所需的字段编号也是动态的..这就是为什么我想传递字段编号和分隔符的参数..
字段编号参数工作正常，但分隔符参数不行？

正如 Anubhava 所建议的，我使用的 fpat 工作得非常好，但是在从输入文件中获取第 5 列时它没有给出任何行？

Answer 1

使用gnu-awk，您可以定义一个FPAT 变量，它是匹配字段的正则表达式。

awk -v FPAT='"[^"]*"|[^,]*' '{gsub(/"/, "", $4); print $4}' file

d,e,f
e,f
s,u

---

从一个以分隔符作为参数的 shell 脚本运行它：

dl="${1?}"
awk -v FPAT='"[^"]*"|[^'"$dl"']*' '{gsub(/"/, "", $4); print $4}' "${2?}"

然后运行如下：

bash p.sh ',' 'file'

Answer 2

那个正则表达式很奇怪，所以我会重写它。正则表达式：

/("[^"]+",|[^,]*,|([^,]+$))/

"[^"]+" 被解析为 - 第一个 " 和最后一个 " 是引号，[^"]+ 匹配除引号之外的所有内容。所以它是一样的：

"([^\"]+,|[^,]*,|([^,]+$))"

我猜你想匹配一个字段[^,]+ 或一个带引号的字段\"[^\"]+\"，后跟一个分隔符或行尾(,|$)。所以匹配那个。并且在匹配组中匹配字段的内部，所以匹配 \"([^\"]+)\" 或未引用的字段 ([^,]+) 然后使用这些匹配组

awk -v dl=, '{
    x = 0;
    while (match($0, "^(\"([^\"]+)\"|([^" dl "]+))(" dl "|$)", a)) {
        $0 = substr($0, RSTART + RLENGTH);
        b[++x] = a[2] a[3];   # funny, one of them will be empty
    }
    print b[4];
}' <<EOF
a,b,c,"d,e,f"
"a,b",c,d,"e,f"
p,q,r,"s,u"
EOF

d,e,f
e,f
s,u