VBA excel宏2文件处理读取合并错误

Question

我正在尝试使用以下代码将 2 个 Excel 工作表合并到第三个工作表中

`Sub CommandButton1_Click()
 Dim MyFile As String
 Dim Filepath As String
 Filepath = "C:\temp\"
 MyFile = Dir(Filepath)
  'MyFile = "12_10_15_par.xlxs"
     'If MyFile = "12_10_15_par.xlsx" Then
     If MyFile = Cells(4, 2) Then
        Workbooks.Open (Filepath & MyFile)
        Worksheets("par").Range("A1:K1000").Copy
        ActiveWorkbook.Close
        ActiveSheet.Paste Destination:=Worksheets("match").Range("T1:AF1001")
        'Application.CutCopyMode = False
     End If
     MyFile2 = Dir(Filepath)
     If MyFile2 = Cells(5, 2) Then
        Workbooks.Open (Filepath & MyFile2)
        Worksheets("ops").Range("A1:K1000").Copy
        ActiveWorkbook.Close
        ActiveSheet.Paste Destination:=Worksheets("match").Range("D1:S1001")
        'Application.CutCopyMode = False
     End If

 End Sub`

也许我做错了，因为 Myfile2 保留了 First 值而不是获取 NEW 值...

Answer 1

这里是Dir()的使用方法，注意循环结束时MyFile = Dir()，它会在循环之前加载MyFile中的下一个文件名！

试试这个：

Sub CommandButton1_Click()
Dim MyFile As String, _
    Filepath As String, _
    oWb As Workbook, _
    pWb As Workbook

Filepath = "C:\temp\"
Set pWb = ThisWorkbook

MyFile = Dir(Filepath)
Do While MyFile <> ""
    If MyFile <> Cells(4, 2) And MyFile <> Cells(5, 2) Then
    Else
        Set oWb = Workbooks.Open(Filepath & MyFile)
        If MyFile <> Cells(5, 2) Then
            oWb.Worksheets("par").Range("A1:K1000").Copy Destination:=pWb.Worksheets("match").Range("T1:AF1001") '4
        Else
            oWb.Worksheets("ops").Range("A1:K1000").Copy Destination:=pWb.Worksheets("match").Range("D1:S1001") '5
        End If
        'Application.CutCopyMode = False
        oWb.Close
    End If
    MyFile = Dir()
Loop

End Sub