将 Excel 工作表合并为值

Question

我正在使用一些代码（通过：http://www.extendoffice.com/documents/excel/1184-excel-merge-multiple-worksheets-into-one.html 找到）来合并 5 张工作表，每张工作表有 1000 行。

Sub Combine()
Dim J As Integer
On Error Resume Next
Sheets(1).Select
Worksheets.Add
Sheets(1).Name = "Combined"
Sheets(2).Activate
Range("A1").EntireRow.Select
Selection.Copy Destination:=Sheets(1).Range("A1")
For J = 2 To Sheets.Count
Sheets(J).Activate
Range("A1").Select
Selection.CurrentRegion.Select
Selection.Offset(1, 0).Resize(Selection.Rows.Count - 1).Select
Selection.Copy Destination:=Sheets(1).Range("A65536").End(xlUp)(2)
Next
End Sub

这似乎工作得很好，除了我需要使用“粘贴为值”方法来组合工作表（因为我的个人工作表有很多公式，我只想将它们组合为文本版本）。

此代码能否轻松更改为“粘贴为值”？

谢谢。

Answer 1

Sub Combine()
Dim J As Integer
On Error Resume Next
Sheets(1).Select
Worksheets.Add
Sheets(1).name = "Combined"
Sheets(2).Activate
Range("A1").EntireRow.Select
Selection.Copy Destination:=Sheets(1).Range("A1")
For J = 2 To Sheets.Count
Sheets(J).Activate
Range("A1").Select
Selection.CurrentRegion.Select
Selection.Offset(1, 0).Resize(Selection.Rows.Count - 1).Copy
Sheets(1).Range("A65536").End(xlUp)(2).PasteSpecial xlPasteValues
Next
End Sub

这行得通吗？如果是这样，我们可以着手处理removing .select 以使其更加“紧凑”。我已经在.Copy 线上做了（你能看到我做了什么吗？）

编辑：这几乎可以实现 - 我认为您会在粘贴部分遇到问题，但我可以解决这个问题。请告诉我，在您的原始代码中，您选择的 CurrentRegion 是什么？试图复制/粘贴什么？

编辑 2：好的，我想我终于明白了。问题是您使用Sheets(1)、Sheets(2)。我不知道您的文档如何，但以下假设适用于这些假设：您有“不变”的工作表处于活动状态（这是带有您的神奇公式的工作表）。只需激活它并运行下面的宏。

Sub Combine()
Dim J As Integer, noRows As Integer
Dim ws1 As Worksheet, ws2 As Worksheet, magicWS As Worksheet

' Note, you need to have the worksheet where you do all of your formulas open and be the active sheet.
Set magicWS = ActiveSheet

Set ws1 = Sheets.Add(after:=magicWS)
ws1.Name = "Combined"

On Error Resume Next

'Now, I assume that your main (unchanging) worksheet is the FAR LEFT most
'Then, the second worksheet is the new "Combined".  If you look along the bottom, every worksheet RIGHT of "Combined" will need
'to be added to this WS.

'First, let's get the headers from the third sheet:
ws1.Cells.Rows(1).Value = Sheets(3).Cells.Rows(1).Value

'Now, let's add the data to "Combined"!
For J = 3 To Sheets.Count
    noRows = Sheets(J).Range("A1").CurrentRegion.Rows.Count
    Sheets(J).Range("A1").CurrentRegion.Offset(1, 0).Resize(noRows - 1).Copy
    ws1.Range("A65536").End(xlUp)(2).PasteSpecial xlPasteValues
Next J

Application.CutCopyMode = False

End Sub