行的交替颜色与前导列中的合并行 - Excel 2016

Question

我正在尝试创建一个 Excel 工作表，用于跟踪我们公司的一些自主流程及其访问权限，但我遇到了 Excel 问题..

我正在尝试交替行颜色，这本身不是问题，但是我已经合并行的事实给我带来了问题。

截至目前，我在 A 到 E 中有 5 列的标题。F 列用于条件格式以对行着色。在 F 列中存在这个公式：

=MOD(IF(ROW()=2,0,IF(A2=A1,F1, F1+1)), 2)

如果我想一遍又一遍地重复前导 Column 项目，这非常有用，但是我想减少视觉混乱并提高清晰度，所以我合并了 A 列中的一些行，因为在B:E 对应。

我现在合并了 A2:A4，公式将 A2 和 A4 选为空白，但 A3（合并单元格中的文本居中）被识别为与 A2 和 A4 不同，因为文本位于那里。我将上传一张图片，以便更好地了解我在说什么。

如果有人可以给我一个提示，告诉我如何用合并的单元格/行交替行颜色，那就太好了，我已经在 stackoverflow 上进行了很多谷歌搜索和搜索，但大多数情况下我只发现与未合并的行/单元格有关的事情。

图片示例：https://imgur.com/a/UDbRVWA

=IF() 对我有用的条件：

=MOD(IF(ROW()=2,0,IF((A2=0),IF((OR(A1<>0,A2=A1)),F1, F1+1),F1+1)), 2)

下面有一个我发布的图片的答案，但是，对于大多数情况，我会推荐@BruceWayne 建议的方法。这比使用合并单元格要明智得多！

Answer 1

我最终找到了一个解决方案，只需巧妙地使用 Conditional IF() 语句。我认为关键是考虑到不是顶部的合并单元格（即，如果我合并 A2:​​A4，A2 是顶部，A3，A4 底部）等于 0，而顶部设置为合并单元格中的文本。使用下面的公式，我能够达到我想要的结果：

=MOD(IF(ROW()=2,0,IF((A2=0),IF((OR(A1<>0,A2=A1)),F1, F1+1),F1+1)), 2)

这是一个链接截图：https://imgur.com/a/gNaC62c

然后我只为除第 1 行之外的每一行添加条件格式：=$F2=1。我将隐藏 F 列以使其看起来不那么突兀。

为了将来的参考，我同意@BruceWayne 提到的更简单的格式来完成工作会更好。还有许多其他方法可以以更有意义的方式对其进行格式化，但是当我修改它时，我觉得我已经很接近了，所以我又坚持了 15 分钟左右，并且能够提取出可用的格式条件。

Answer 2

我可以提个建议吗？如果合并行是为了增加重复条目的清晰度，也许我们可以使用另一个条件格式规则来使其更清晰。

假设您有如下所示的数据：

但是，我们不希望在 A 列中看到 <Process #> 重复项。我们可以合并这些单元格并将其沿行居中。但同样，我发现合并单元格通常不受欢迎。 （格式化、条件格式、复制/粘贴、做任何VLOOKUP()/Index/Match 等都很棘手）

首先，让我们让行交替颜色。我正在使用 RGB(183, 255, 253) 的填充：

新规则 1 -
公式：=MOD(ROW(),2)
适用范围：$A$2:$E$9
格式：填充颜色 RGB 183、255、253（...或任何你想要的，只需记下 RGB 以备后用）

现在，我们得到了这个：

好的，正在取得进展。现在，让我们来隐藏 A 列中的重复值。

所以，让我们应用更多的条件格式。我们需要两个用于 A 列，一个将字体设置为白色，一个将字体设置为蓝色填充颜色。

新规则 2 -
公式：=AND($A3=$A2,MOD(ROW(),2)=1)
适用于：=$A$3:$A$100
格式：字体 --> 颜色 --> RGB(183, 255, 253)

新规则 3 -
公式：=AND($A3=$A2,MOD(ROW(),2)=0)
适用于：=$A$3:$A$100
格式：字体 --> 颜色 --> 白色

现在我们有：

IMO，我们可以再做一件事来澄清流程中的中断：

新规则 4 -
公式：=$A2<>$A1
适用于：=$A$2:$E$100
格式：边框 --> 上边框

现在，我们有了一个不错的新 CF 表。