合并单元格的宏

Question

我有一个 Excel 文件，其中 B 列中有发票编号 (B2:B14987)，在 C 列中我有项目 ID，在 D 列中我有销售价值，在 E 列中我有发票折扣值。

我需要一个宏来合并基于发票编号列的发票折扣值单元格，发票编号重复，因为一张发票中有不同的项目 ID。

例如：B1:B3 是相同的发票编号，E1 是发票的常见折扣值，B1:B3，E2:E3 是空白单元格。所以我希望 E1:E3 与 E1 中的值合并。

Answer 1

以下代码可以满足您的要求；一如既往，如果我误解了，请澄清问题，我们会到达那里......

在您的电子表格中创建一个模块，然后粘贴以下代码：

Private Sub mergeAndAlign(r As Range)
    With r
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .MergeCells = True
    End With
End Sub

Sub mergeAll()
' step through column E
' merge all cells that have the same invoice number
' they are already sorted - and the value we need is in the first cell
' of the block to be merged
Dim r As Range
Dim prevItem As Range
Dim nextItem As Range
Dim lastRow, thisRow, rCount As Integer

lastRow = [B2].End(xlDown).Row

Set prevItem = [E2]
Set nextItem = prevItem.End(xlDown)

While nextItem.Row <= lastRow
  Set r = Range(prevItem, nextItem.Offset(-1, 0))
  mergeAndAlign r
  Set prevItem = nextItem
  Set nextItem = nextItem.End(xlDown)
Wend

' do the last item:
Set nextItem = Cells(lastRow, 5) ' last valid cell in column E
Set r = Range(prevItem, nextItem)
mergeAndAlign r

End Sub

从感兴趣的工作表中运行代码。单击 Alt-F8 以调出“宏”对话框 - 您应该会在列表中看到“MergeAll”项（可能是唯一一项）。它会带你从这里开始：

到这里：