【问题标题】:VBA Collection Class: Unwated Data OverwritingVBA 集合类:未完成的数据覆盖
【发布时间】:2018-04-21 04:54:22
【问题描述】:

我有一个集合类(或者更确切地说是字典类,在这种情况下),用于存储可变数量的边缘对象。当我尝试通过循环填充包含所有信息的字典时,数据不断被覆盖,我似乎无法弄清楚原因。相关类的代码如下:

Option Explicit

Private pEdges As New Scripting.Dictionary

Property Get Count() As Long
    Count = pEdges.Count
End Property

Property Get EdgeByName(ByVal iName As Variant) As cEdge
    Set EdgeByName = pEdges(iName)
End Property

'Would it be better to pass all of the data to this add sub, and create 
'the class objects here, rather than creating a temporary class object and 
'just passing it along?
Sub Add(ByVal iEdge As cEdge)
    Dim Edge As New cEdge
    Set Edge = iEdge
    pEdges.Add Edge.Name, Edge
End Sub

Sub Remove(ByVal iName As Variant)
    pEdges.Remove (iName)
End Sub

Sub RemoveAll()
    pEdges.RemoveAll
End Sub

Sub PrintNames()
    Dim Key As Variant
    For Each Key In pEdges
        Debug.Print Key & " - " & pEdges(Key).Name & vbCrLf;
    Next
    Debug.Print vbdrlf;
End Sub

生成 Edges 对象的子如下:

Sub CalculateEdges(cCavities() As cCavity, dEdges As cEdges)
    Dim i As Integer

    For i = 1 To UBound(cCavities)
        Dim TempEdge As cEdge
        Set TempEdge = New cEdge
        Dim AdjSize As Integer
        AdjSize = cCavities(i).AdjacencySize
        If AdjSize> MaxEdges Then MaxEdges = AdjSize
        Dim j As Integer
        For j = 1 To AdjSize
            With TempEdge
                'Edge Names are a combination of two node names
                .Name = cCavities(i).Name & cCavities(i).Adjacency(j)
                'Sets the start node (Object) for the edge
                .SetNode cCavities(i), 0
                'Sets the end node (Object) for the edge
                .SetNode BackGround.NodeByName(cCavities, cCavities(i).Adjacency(j)), 1
                'Used later in program
                .Value = 0
            End With
            dEdges.Add TempEdge
            dEdges.PrintNames
        Next j
    Next i
End Sub

dEdges.PrintNames sub 的输出是我一直用来调试的(因为 Watches 窗口不显示字典的项目数据)。 随着循环的进行,它会打印键对应的边缘对象的键和名称值。如果工作正常,这两个字符串应该是相同的。尽管如此,每次我向字典中添加一个新的边缘对象时,它都会覆盖所有先前输入的键的对象。我怀疑这与我创建一个 TempEdge 变量以传递给 Collection 类的事实有关,但我不确定。

输出示例:

C1C2 - C1C2

C1C2 - C1C3
C1C3 - C1C3

C1C2 - C1C4
C1C3 - C1C4
C1C4 - C1C4

ETC

这只是一个正在测试的单个数据点,但我向您保证,cEdge 对象内的所有变量都被覆盖,而不仅仅是名称字符串。它只是最容易检查的,因为它只是一个字符串。

作为旁注,如果有一种方法可以查看存储在字典中的对象,类似于“Watches”窗口,我非常想知道该怎么做。我什至在这一点上使用临时边缘的全部原因是我可以跟踪循环中任何给定点进入字典的数据。

第二个附注,如果我能做到这一点,我很可能会将 cCavities 数组切换到类似的集合类。它目前不是一个,因为我似乎无法让它们正常工作。

【问题讨论】:

    标签: vba class dictionary collections


    【解决方案1】:

    将 Set "TempEdge = New cEdge" 移动到循环中将在每个循环中创建一个新实例和一个新指针位置,同时保持集合对先前指针的引用。

    Sub CalculateEdges(cCavities() As cCavity, dEdges As cEdges)
    Dim i As Integer
    
    For i = 1 To UBound(cCavities)
        Dim TempEdge As cEdge
    
    
    
        Dim AdjSize As Integer
        AdjSize = cCavities(i).AdjacencySize
        If AdjSize> MaxEdges Then MaxEdges = AdjSize
        Dim j As Integer
        For j = 1 To AdjSize
            Set TempEdge = New cEdge
            With TempEdge
                'Edge Names are a combination of two node names
                .Name = cCavities(i).Name & cCavities(i).Adjacency(j)
                'Sets the start node (Object) for the edge
                .SetNode cCavities(i), 0
                'Sets the end node (Object) for the edge
                .SetNode BackGround.NodeByName(cCavities, cCavities(i).Adjacency(j)), 1
                'Used later in program
                .Value = 0
            End With
            dEdges.Add TempEdge
            dEdges.PrintNames
        Next j
    Next i
    

    结束子

    【讨论】:

      【解决方案2】:

      我继续提出将所有数据传递给添加例程的想法,它似乎已经解决了这个问题。不过,我仍然想知道为什么我使用的方法不起作用,所以请随时对此发表评论或回答。

      解决方案是更改 cEdges.Add Sub 以接受曾经传递给临时边缘变量的所有单个参数:

      Sub Add(ByVal iName As String, iNode1 As cCavity, iNode2 As cCavity, iValue As Integer)
          Dim Edge As New cEdge
          With Edge
              .Name = iName
              .SetNode iNode1, 0
              .SetNode iNode2, 1
              .Value = iValue
          End With
          pEdges.Add Edge.Name, Edge
      End Sub
      

      这会将填充循环更改为:

      Sub CalculateEdges(cCavities() As cCavity, dEdges As cEdges)
          Dim i As Integer
      
          For i = 1 To UBound(cCavities)
              Dim AdjSize As Integer
              AdjSize = cCavities(i).AdjacencySize
              If AdjSize > MaxEdges Then MaxEdges = AdjSize
              Dim j As Integer
              For j = 1 To AdjSize
                  dEdges.Add cCavities(i).Name & cCavities(i).Adjacency(j), cCavities(i), BackGround.NodeByName(cCavities, cCavities(i).Adjacency(j)), 0
                  dEdges.PrintNames
              Next j
          Next i
      End Sub
      

      这段代码,尤其是 .Add 行,可以被清理掉。我很可能会这样做,但现在这很好。

      编辑:经过进一步研究和反复试验,我发现了数据被覆盖的原因。 Set 关键字只创建一个指向原始值的指针,有效地使我上面的代码有一个对象,即 TempEdge 变量,以及一大堆指向它的不同头。这就是为什么当编辑 Temp 边缘时,所有后续的磁头都会改变。

      【讨论】:

        猜你喜欢
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        • 2018-01-18
        • 2023-04-08
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        相关资源
        最近更新 更多