我想创建一个脚本，它将文件从一个文件夹复制到另一个文件夹。
由于文件可能很大，最高可达 1000 MB，因此可能需要几秒钟的时间 或一分钟完全复制它。发生这种情况时，我希望目标文件夹中的文件名带有下划线（_）前缀。
文件完全复制到目标文件夹后，应从文件名中删除_。这样做的目的是确保另一个进程不应该从目标文件夹中提取不完整的文件。
我们如何使用批处理脚本来做到这一点？目前我的批处理文件正在复制并将文件移动到另一个文件夹，但我不知道如何在文件完全移动后添加下划线前缀，然后再次从文件名中删除。
这是我复制和移动文件的两行代码。
copy %1\Customer_*.xml C:\Users\ard\Documents\Folder1
move %1\Customer_*.xml %1\Archive
如果这不能使用批处理脚本完成，那么 VB 脚本也应该可以工作
【问题讨论】：
标签： batch-file vbscript
删除前缀并非易事，但删除后缀（新扩展名）很简单。所以我会附加一个新的扩展，比如.inProgress。然后，您可以使用通配符使用两个简单的命令来复制和重命名文件集合。
但是 MOVE 命令不允许重命名多个文件，因此需要一个 FOR 循环。我将展示代码，但我认为在 OP 的场景中这并不是真正必要的。在我看来，源文件夹和目标文件夹位于同一个驱动器上，因此移动应该几乎是即时的，并且不需要使用临时中间名。
copy "%1\Customer_*.xml" "C:\Users\ard\Documents\Folder1\*.*.inProgress"
ren "C:\Users\ard\Documents\Folder1\*.inProgress" *.
for %%F in ("%1\Customer_*.xml") do (
move "%%F" "%1\Archive\%%~nxF.inProgress"
ren "%1\Archive\%%~nxF.inProgress" *.
)
请参阅How does the Windows RENAME command interpret wildcards?，了解重命名的原因。
请注意，在整个 COPY 操作完成之前，所有复制的文件都将显示为“.inProgress”。如果您希望每个文件尽快可用，那么 COPY 也需要一个 FOR 循环：
for %%F in ("%1\Customer_*.xml") do (
copy "%%F" "C:\Users\ard\Documents\Folder1\%%~nxF.inProgress"
ren "C:\Users\ard\Documents\Folder1\%%~nxF.inProgress" *.
)
【讨论】：
我的示例使用新名称从 src 复制到 dest，然后恢复旧名称： bn 是源文件的基本名称。
for %%a in (src\*.xml) do (
set bn=%%~nxa
copy %%a dest\!bn!_
rename dest\!bn!_ !bn!
)
【讨论】：
set bn=%%~nxa 会更好（它也会消除对enabledelayedexpansion 的依赖）
你想要什么，用文字表达：
对于C:\source中的每个受影响的文件：
x复制到C:\destination\_x
C:\destination\_x 重命名为C:\destination\x
在 Windows 批处理代码中，还有一些附加功能：
@echo off
setlocal
set "SOURCE=%1"
set "DESTINATION=C:\Users\ard\Documents\Folder1"
for /f "usebackq delims=" %%x in (`dir /b "%SOURCE%\Customer_*.xml"`) do (
if exist "%DESTINATION%\%%x" (
echo %%x - already exists at destination
) else (
echo %%x
copy "%SOURCE%\%%x" "%DESTINATION%\_%%x" > NUL && rename "%DESTINATION%\_%%x" "%%x"
)
)
注意事项：
for 循环可以逐行迭代命令的输出dir /b "%SOURCE%\*.xml"，即源文件夹中匹配文件的“裸”列表usebackq 表示命令由反引号分隔，允许在命令本身内使用双引号delims= 将字段分隔符设置为“无”，否则 for 会将每个文件名拆分为标记（如果它包含空格）> NUL 禁止“复制 1 个文件”。来自copy 的成功消息
&& 表示 rename 仅在 copy 成功时执行【讨论】：