Groovy 复制/组合来自多个对象的元方法

Question

我有两节课。在运行时，我想将一个对象的方法“克隆”到另一个对象。这可能吗？我使用 leftshift 的失败尝试如下所示。

（注意：我也尝试了 currMethod.clone() 得到相同的结果。）

class SandboxMetaMethod2 {
    String speak(){
        println 'bow wow'
    }
}

class SandboxMetaMethod1{

  void leftShift(Object sandbox2){
      sandbox2.metaClass.getMethods().each{currMethod->
          if(currMethod.name.contains("speak")){
              this.speak()
              this.metaClass."$currMethod.name" = currMethod
              this.speak()
          }
      }
  }

  String speak(){
    println 'woof'
  }
}

class SandboxMetaMethodSpec extends Specification {
    def "try this"(){
        when:
        def sandbox1 = new SandboxMetaMethod1()
        def sandbox2 = new SandboxMetaMethod2()
        sandbox1 << sandbox2


        then:
        true
    }

}


//Output
woof
speak
woof

根据请求，我正在为目标/用例添加背景：

它非常类似于标准功能类型的用例。总之，我们有很多适用于我们所有客户端环境（50-100）的类的方法。我们将它们应用于以特定默认顺序处理数据。这些方法中的每一个都可以被客户端特定的方法覆盖（如果它们存在相同的方法名称），并且想法是使用上面的方法来“协调”方法集。根据客户端环境名称，我们需要一种动态覆盖方法的方法。

注意：在元类上覆盖方法是非常标准的（或者我应该说，这就是存在惊人功能的原因）。如果我的方法以 String currMethod = "{x-> x+1}" 之类的文本形式存在，它就可以工作，那么我就说 this.metaClass."$currMethodName" = currMethod。在这种情况下，我的挑战是我的方法已编译并存在于另一个类中，而不是在某处被定义为文本。

在构建时将所有自定义方法编译到特定于客户端的类中的目的是避免在运行时为每次计算编译这些动态方法的费用，因此所有特定于客户端的方法都编译到单独的客户端-构建时的特定 JAR。这种方式还允许我们只将特定于客户端的代码部署到相应的客户端，而无需在某个主类中进行所有其他客户端计算。

我希望这是有道理的。

新方法，响应 Jeremie B 的建议：

由于我需要在运行时按名称选择要实现的特征，所以这样的工作是否可行：

String clientName = "client1"
String clientSpeakTrait = "${clientName}Speak"

trait globalSpeak {
    String speak() {
        println 'bow wow'
    }
}

trait client1Speak {
    String speak() {
        println 'woof'
    }
}

def mySpeaker = new Object().withTraits globalSpeak, clientSpeakTrait

Answer 1

带有 Traits 的基本示例：

trait Speak {
    String speak() {
        println 'bow wow'
    }
}

class MyClass {

}

def instance = new MyClass()
def extended = instance.withTraits Speak

extended.speak()

您可以选择在运行时使用哪个特征：

def clientTrait = Speak
def sb = new Object().withTraits(clientTrait)

sb.speak()

并使用 ClassLoader 动态加载特征：

def clientTrait = this.class.classLoader.loadClass "my.package.${client}Speak"
def sb = new Object().withTraits(clientTrait)