如何获得所有显示器的比例因子？

Question

微软不知道如何帮助我，所以我不得不在这里问。

我有三台显示器...

• 屏幕 1：3840 x 2160，缩放 150%
• 屏幕 2：1920 x 1200，缩放 100%
• 屏幕 3：1920 x 1200，缩放 100%

我需要在VB.net 或C# 中获取每个监视器的缩放比例。

Microsoft 建议我使用此代码：

Private Declare Function GetDeviceCaps Lib "gdi32.dll" (hdc As IntPtr, nIndex As Integer) As Integer

Public Enum DeviceCap
    VERTRES = 10
    DESKTOPVERTRES = 117
End Enum

Private Sub MainWindow_Loaded(sender As Object, e As RoutedEventArgs) Handles Me.Loaded
    For Each screen As Forms.Screen In Forms.Screen.AllScreens
        Dim pnt = New System.Drawing.Point(screen.Bounds.Left + 1, screen.Bounds.Top + 1)
        Dim mon = MonitorFromPoint(pnt, 2)
        Dim fac As Single = GetScalingFactor(mon)
        Console.WriteLine($"Factor: {fac}")
    Next
End Sub

Private Function GetScalingFactor(monitorHandle As IntPtr) As Single
    Dim g As Graphics = Graphics.FromHwnd(IntPtr.Zero)
    Dim desktop As IntPtr = g.GetHdc()
    Dim LogicalScreenHeight As Integer = GetDeviceCaps(desktop, CInt(DeviceCap.VERTRES))
    Dim PhysicalScreenHeight As Integer = GetDeviceCaps(desktop, CInt(DeviceCap.DESKTOPVERTRES))
    Dim ScreenScalingFactor As Single = CSng(PhysicalScreenHeight) / CSng(LogicalScreenHeight)
    Return ScreenScalingFactor
End Function

但它为我的所有屏幕返回 1 的比例。

我需要它独立于我的应用是否支持 dpiAware，因此我必须以某种方式从屏幕控制面板读取它。

该解决方案必须适用于 Windows 10 和 Windows Server 2012 R2 远程桌面客户端。

Answer 1

我相信您可以在DisplayInformation 类中使用ResolutionScale 属性。这会为您检索一个带有比例因子的枚举，但我不知道它是否独立于 dpiAware。

Answer 2

这可能会对您有所帮助。

通常屏幕显示器的 rawDpi 为 102 点 x 英寸，但如果你有一个 Microsft Surface is logic 你有另一个 rawDpi。 所以在这种情况下，您可以使用真实设备 rawDpi 更改 102（您可以通过 100% 屏幕分辨率下的代码获得）

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

    For Each screen In System.Windows.Forms.Screen.AllScreens

        Dim mRawSreen As SCREENS = Display(screen, DpiType.MDT_RAW_DPI)

        Console.WriteLine(" deviceName: " & screen.DeviceName &
                          " ScaleFactorX: " & (102 / mRawSreen.DPI_X * 100).ToString("N2") & "%" &
                          " ScaleFactorY: " & (102 / mRawSreen.DPI_Y * 100).ToString("N2") & "%")

    Next

End Sub

Public Enum DpiType
    MDT_EFFECTIVE_DPI = 0
    MDT_ANGULAR_DPI = 1
    MDT_RAW_DPI = 2
End Enum

Structure SCREENS
    Dim DPI_X As Integer
    Dim DPI_Y As Integer
End Structure

Private Function Display(screen As Screen, ByVal type As DpiType) As SCREENS

    Dim x, y As UInteger

    GetDpi(screen, type, x, y)

    Dim current As SCREENS = New SCREENS With {
            .DPI_X = x,
            .DPI_Y = y
            }

    'Console.WriteLine(" deviceName: " & screen.DeviceName & " typeDpi: " & type.ToString & " : dpiX=" & x & ", dpiY=" & y)
    Return current

End Function

Private Declare Function MonitorFromPoint Lib "User32.dll" (ByVal pt As System.Drawing.Point, ByVal dwFlags As UInteger) As IntPtr
Private Declare Function GetDpiForMonitor Lib "Shcore.dll" (ByVal hmonitor As IntPtr, ByVal dpiType As DpiType, ByRef dpiX As UInteger, ByRef dpiY As UInteger) As IntPtr

Sub GetDpi(ByVal screen As System.Windows.Forms.Screen, ByVal dpiType As DpiType, ByRef dpiX As UInteger, ByRef dpiY As UInteger)
    Dim pnt = New System.Drawing.Point(screen.Bounds.Left + 5, screen.Bounds.Top + 5)
    Dim mon = MonitorFromPoint(pnt, 2)
    GetDpiForMonitor(mon, dpiType, dpiX, dpiY)
End Sub