可选的命名参数，而不将它们全部包装在“OptionValue”中

Question

假设我有一个带有可选命名参数的函数，但我坚持通过它们的朴素名称来引用这些参数。

考虑这个添加了两个命名参数 a 和 b 的函数：

Options[f] = {a->0, b->0};  (* The default values. *)
f[OptionsPattern[]] := 
  OptionValue[a] + OptionValue[b]

我如何编写该函数的一个版本，其中最后一行被简单地替换为a+b？ （想象一下 a+b 是一大堆代码。）

以下问题的答案显示了如何缩写OptionValue（说起来容易做起来难），而不是如何完全摆脱它：Optional named arguments in Mathematica

哲学附录：看起来如果 Mathematica 将拥有 OptionsPattern 和 OptionValue 的魔力，它还不如一路走下去，并有一个语言结构来正确处理命名参数，你可以在其中引用它们你知道，他们的名字。就像所有其他具有命名参数的语言一样。 （与此同时，我很好奇有什么变通办法……）

Answer 1

这是我的答案的最终版本，其中包含 Brett Champion 答案的贡献。

ClearAll[def];
SetAttributes[def, HoldAll];
def[lhs : f_[args___] :> rhs_] /; !FreeQ[Unevaluated[lhs], OptionsPattern] :=
   With[{optionNames = Options[f][[All, 1]]},
     lhs := Block[optionNames, optionNames = OptionValue[optionNames]; rhs]];
def[lhs : f_[args___] :> rhs_] := lhs := rhs;

之所以在论证中作为延迟规则给出定义，是因为这样我们可以 受益于语法高亮。使用块技巧是因为它适合问题：它不会干扰函数内部可能的嵌套词法范围构造，因此不会有意外捕获变量的危险。我们检查 OptionsPattern 的存在，因为没有它，这段代码对于定义是不正确的，我们希望 def 在这种情况下也能工作。 使用示例：

Clear[f, a, b, c, d];
Options[f] = {a -> c, b -> d};
(*The default values.*)
def[f[n_, OptionsPattern[]] :> (a + b)^n]

您现在可以查看定义：

Global`f
f[n$_,OptionsPattern[]]:=Block[{a,b},{a,b}=OptionValue[{a,b}];(a+b)^n$]

f[n_,m_]:=m+n

Options[f]={a->c,b->d}

我们现在可以测试了：

In[10]:= f[2]
Out[10]= (c+d)^2

In[11]:= f[2,a->e,b->q]
Out[11]= (e+q)^2

修改是在“编译时”完成的，并且非常透明。虽然此解决方案可以节省 一些打字w.r.t。 Brett's，它在“编译时”确定选项名称集，而 Brett's - 在“运行时”确定。因此，它比 Brett 的要脆弱一点：如果您在使用 def 定义函数后添加一些新选项，则必须清除它并重新运行 def。然而，在实践中，习惯上从 ClearAll 开始并将所有定义放在一个部分（单元格）中，因此这似乎不是一个真正的问题。此外，它不能与字符串选项名称一起使用，但您的原始概念也假定它们是符号。此外，它们不应该有全局值，至少在 def 执行时没有。

Answer 2

为什么不直接使用类似的东西：

Options[f] = {a->0, b->0};
f[args___] := (a+b) /. Flatten[{args, Options[f]}]

对于更复杂的代码，我可能会使用类似的代码：

Options[f] = {a->0, b->0};
f[OptionsPattern[]] := Block[{a,b}, {a,b} = OptionValue[{a,b}]; a+b]

并使用对 OptionValue 的一次调用来一次获取所有值。 （主要原因是如果存在未知选项，这会减少消息。）

更新，以编程方式从选项列表中生成变量：

Options[f] = {a -> 0, b -> 0};
f[OptionsPattern[]] := 
  With[{names = Options[f][[All, 1]]}, 
    Block[names, names = OptionValue[names]; a + b]]

Answer 3

这是一种可怕的解决方案：

Options[f] = {a->0, b->0};
f[OptionsPattern[]] := Module[{vars, tmp, ret},
  vars = Options[f][[All,1]];
  tmp = cat[vars];
  each[{var_, val_}, Transpose[{vars, OptionValue[Automatic,#]& /@ vars}],
    var = val];
  ret = 
    a + b;  (* finally! *)
  eval["ClearAll[", StringTake[tmp, {2,-2}], "]"];
  ret]

它使用以下便利功能：

cat = StringJoin@@(ToString/@{##})&;        (* Like sprintf/strout in C/C++.  *)
eval = ToExpression[cat[##]]&;              (* Like eval in every other lang. *)
SetAttributes[each, HoldAll];               (* each[pattern, list, body]      *)
each[pat_, lst_, bod_] := ReleaseHold[      (*  converts pattern to body for  *)
  Hold[Cases[Evaluate@lst, pat:>bod];]];    (*   each element of list.        *)

请注意，如果 a 或 b 在调用函数时具有全局值，则此方法不起作用。但无论如何，对于 Mathematica 中的命名参数，情况总是如此。