perl：捕获替换为字符串

Question

我的循环代码类似于

for( my $i=0; $a =~ s/<tag>(.*?)<\/tag>/sprintf("&CITE%03d;",$i)/e ; $i++ ){  
    %cite{ $i } = $1;  
    }

但不只是整数索引，我想让散列的键实际替换为文本（占位符“&CITE001;”等），而不必重做 sprintf()。

我几乎可以肯定有办法做到这一点（类似于 $& 等的变量，但也许我在考虑 vim 的替换而不是 perl。:)

谢谢！

Answer 1

my $i = 0;
s{<tag>(.*?)</tag>}{
   my $entity = sprintf("&CITE%03d;", $i++);
   $cite{$entity} = $1;
   $entity
}eg;

Answer 2

我做了一些简单的事情，但我真的想要一些更优雅的东西。我最终做的（现在）是

my $t;  
for( my $i=0; $t = sprintf("&CITE%04d;",$i), $all =~ s/($oct.*?$cct)/$t/s; $i++ ){  
    $cites{$t} = $1;  
    }

但我真的想要一些更“独立”的东西。

不过，只要能够获取替换字符串，事情就会变得简单得多。这是一个简单的读-修改-写操作。

没错，添加“g”修饰符应该有助于减少一些微秒。 :D

Answer 3

我认为除了从目标开始重新开始搜索之外的任何方法
总是是更好的选择。

在这种情况下，作为替代方案，您可以在正则表达式中移动逻辑
通过 代码构造 (?{ code }) 并利用 $^N 包含的事实
最后捕获的内容。

Perl

use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

my $target = "<tag>zero</tag>\n<tag>one</tag>\n<tag>two</tag>\n<tag>three</tag>";

my %cite;
my ($cnt,$key) = (0,'');

$target =~ s/
    <tag> (.*?) <\/tag>
    (?{
      $key = sprintf("&CITE%03d;", $cnt++);
      $cite{$key} = $^N;
    })
  /$key/xg;

print $target, "\n";

print Dumper(\%cite);

输出

&CITE000;
&CITE001;
&CITE002;
&CITE003;
$VAR1 = {
          '&CITE000;' => 'zero',
          '&CITE001;' => 'one',
          '&CITE002;' => 'two',
          '&CITE003;' => 'three'
        };

---

@Ikegami 编辑/编码

use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

sub f {
    my $target = "<tag>zero</tag>\n<tag>one</tag>\n<tag>two</tag>\n<tag>three</tag>";

    my %cite;
    my ($cnt,$key) = (0,'');

    $target =~ s/
        <tag> (.*?) <\/tag>
        (?{
          $key = sprintf("&CITE%03d;", $cnt++);
          $cite{$key} = $^N;
        })
      /$key/xg;

    print $target, "\n";

    print Dumper(\%cite);
}

f() for 1..2;

输出

Variable "$key" will not stay shared at (re_eval 1) line 2.
Variable "$cnt" will not stay shared at (re_eval 1) line 2.
Variable "%cite" will not stay shared at (re_eval 1) line 3.
&CITE000;
&CITE001;
&CITE002;
&CITE003;
$VAR1 = {
          '&CITE000;' => 'zero',
          '&CITE001;' => 'one',
          '&CITE002;' => 'two',
          '&CITE003;' => 'three'
        };




$VAR1 = {};

此问题已在 5.18 中解决。

---

@sln 编写的 Perl

看，现在我在 5.20 版中没有遇到这个问题。
而且，我也不相信我在 5.12 中得到了它。

use strict;
use warnings;

use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

sub wrapper {
   my ($targ, $href) = @_;
   my ($cnt, $key) = (0,'');
   $$targ =~ s/<tag>(.*?)<\/tag>(?{ $key = sprintf("&CITE%03d;", $cnt++); $href->{$key} = $^N; })/$key/g;
}

my ($target,%cite) = ("<tag>zero</tag>\n<tag>one</tag>\n<tag>two</tag>\n<tag>three</tag>", ());
wrapper( \$target, \%cite );
print $target, "\n";
print Dumper(\%cite);

($target,%cite) = ("<tag>zero</tag>\n<tag>one</tag>\n<tag>two</tag>\n<tag>three</tag>", ());
wrapper( \$target, \%cite );
print $target, "\n";
print Dumper(\%cite);

输出

&CITE000;
&CITE001;
&CITE002;
&CITE003;
$VAR1 = {
          '&CITE000;' => 'zero',
          '&CITE001;' => 'one',
          '&CITE002;' => 'two',
          '&CITE003;' => 'three'
        };
&CITE000;
&CITE001;
&CITE002;
&CITE003;
$VAR1 = {
          '&CITE000;' => 'zero',
          '&CITE001;' => 'one',
          '&CITE002;' => 'two',
          '&CITE003;' => 'three'
        };