Google表格公式中的多个正则表达式匹配

Question

我正在尝试使用 Google 表格正则表达式公式获取给定字符串中连字符之前的所有数字的列表（假设在单元格 A1 中）：

=REGEXEXTRACT(A1, "\d-")

我的问题是它只返回第一个匹配项...我怎样才能获得所有匹配项？

示例文本：

"A1-Nutrition;A2-ActPhysiq;A2-BioMeta;A2-Patho-jour;A2-StgMrktg2;H2-Bioth2/EtudeCas;H2-Bioth2/Gemmo;H2-Bioth2/Oligo;H2-Bioth2/Opo;H2-Bioth2/Organo;H3-Endocrino;H3-Génétiq"

我的公式返回1-，而我想得到1-2-2-2-2-2-2-2-2-2-3-3-（作为数组或连接文本）。

我知道我可以使用脚本或其他函数（如 SPLIT）来实现所需的结果，但我真正想知道的是如何获得 re2 正则表达式以在 "@ 987654328@" 谷歌表格公式。 类似于regex101.com

上的“global - 第一场比赛后不返回”选项

我还尝试使用 REGEXREPLACE 删除不需要的文本，但也没有成功（我无法删除没有连字符前的其他数字）。

任何帮助表示赞赏！ 谢谢:)

Answer 1

编辑

我想出了更通用的解决方案：

=regexreplace(A1,"(.)?(\d-)|(.)","$2")

它将除第二组匹配 (\d-) 之外的任何文本替换为仅第二组 $2。

"(.)?(\d-)|(.)"
  1    2    3  
  Groups are in ()
  ---------------------------------------
 "$2" -- means return the group number 2

学习正则表达式：https://regexone.com

---

试试这个公式：

=regexreplace(regexreplace(A1,"[^\-0-9]",""),"(\d-)|(.)","$1")

它将像这样处理字符串：

"A1-Nutrition;A2-ActPhysiq;A2-BioM---eta;A2-PH3-Généti***566*9q"

带输出：

1-2-2-2-3-

Answer 2

您可以在脚本编辑器中创建自己的自定义函数：

function ExtractAllRegex(input, pattern,groupId) {
  return Array.from(input.matchAll(new RegExp(pattern,'g')), x=>x[groupId]);
}

或者，如果您需要返回单个单元格中的所有匹配项，并用一些分隔符连接：

function ExtractAllRegex(input, pattern,groupId,separator) {
  return Array.from(input.matchAll(new RegExp(pattern,'g')), x=>x[groupId]).join(separator);
}

那么，就叫它=ExtractAllRegex(A1, "\d-", 0, ", ")吧。

说明：

• input - 当前单元格值
• pattern - 正则表达式模式
• groupId - 正在捕获要提取的组 ID
• separator - 用于加入匹配结果的文本。

Answer 3

我无法获得适用于我的案例的公认答案。我想这样做，但需要一个快速的解决方案并采用以下方法：

输入：

1111 days, 123 hours 1234 minutes and 121 seconds

预期输出：

1111 123 1234 121

公式：

=split(REGEXREPLACE(C26,"[a-z,]"," ")," ")

Answer 4

您实际上可以在单个公式中使用 regexreplace 来使用捕获组包围所有值，而不是替换文本：

=join("",REGEXEXTRACT(A1,REGEXREPLACE(A1,"(\d-)","($1)")))

基本上它所做的是将\d- 的所有实例用一个“捕获组”包围，然后使用正则表达式提取，它巧妙地返回所有捕获。如果你想将它重新加入一个字符串，你可以使用 join 将它重新打包成一个单元格：

Answer 5

这似乎有效，我已尝试验证它。

逻辑是

(1) 将后跟连字符的字母替换为空

(2) 将任何不带连字符的数字替换为空

(3) 将不是数字或连字符的所有内容替换为空

=regexreplace(A1,"[a-zA-Z]-|[0-9][^-]|[a-zA-Z;/é]","")

结果

1-2-2-2-2-2-2-2-2-2-3-3-

分析

我必须在程序上逐步完成这些以说服自己这是正确的。根据this reference，当存在由管道符号分隔的替代方案时，正则表达式应按从左到右的顺序匹配它们。除非规则 1 首先出现，否则上述公式无法正常工作（否则它会在规则 (1) 生效之前将除数字或连字符之外的所有字符减少为空，并且您会从“Patho-jour”中获得一个额外的连字符）。

以下是我认为它必须如何处理文本的一些示例