Flex (Spark) 中从皮肤到视图的数据绑定

Question

我对 Spark 中的 Flex 开发还很陌生，想阐明构建组件的最佳方式。

我之前曾尝试使用绑定表达式来设置 ViewStack 的选定索引：

public class MyComponentView extends SkinnableComponent
{
    public var selectedIndex:int = 0;

}

<s:Skin ...>
    <mx:ViewStack selectedIndex="{hostComponent.selectedIndex}">
            ....
    </mx:ViewStack>
</s:Skin ...>

然而，这个绑定表达式似乎不起作用，尽管如果我将该绑定表达式移到 s:Label 上，它会显示正确的数字。

为了让它工作，我更改了代码：

public class MyComponentView extends SkinnableComponent
{
    [SkinPart(required = "true")]
    public var myStack:ViewStack;

    private var _selectedIndex:int = 0;

    private var _indexChanged:Boolean;

    public function set selectedHistoryIndex(value:int):void
    {
        _selectedIndex = value;
        _indexChanged = true;
        invalidateProperties();
    }

    override protected function partAdded(partName:String, instance:Object):void
    {
        super.partAdded(partName, instance);

        switch (instance)
        {
            case myStack:
                _indexChanged = true;
                invalidateProperties();
                break;
        }
    }

    override protected function commitProperties():void
    {
        super.commitProperties();

        if (_indexChanged && myStack)
        {
            _indexChanged = false;
            myStack.selectedIndex = _selectedIndex;
        }
    }

}

<s:Skin ...>
    <mx:ViewStack id="myStack">
            ....
    </mx:ViewStack>
</s:Skin ...>

这是我打算这样做的方式吗？

Answer 1

对我来说，你的第二种方式更可取。我宁愿更改一些代码以使其更好：

public function set selectedHistoryIndex(value:int):void
{
    if (_selectedIndex == value)
        return;
    _selectedIndex = value;
    _indexChanged = true;
    invalidateProperties();
}

是的，您可以从皮肤绑定到组件的属性，但是这样 View（Spark 架构中的皮肤适用于 MVC 中的视图，宿主组件适用于 M 和 C）对 M 的了解并不好。第一个实现需要来自皮肤的这些知识。

第二个实现使 View 成为真正的 View（由 M 管理）。而且很好。