如何在对象检查器中对组件的属性进行分组？

Question

我希望我的非可视组件将其发布的属性置于不在 Object Inspector 顶层的类别下。

举个例子：

type
  TMyComponent = class(TComponent)
  protected
    function GetSomeValue: string;
    function GetSomeValueExt: string;
  published
    property SomeValue: string read GetSomeValue;
    property SomeValueExt: string read GetSomeValueExt;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('My Component', [TMyComponent]);
end;

function TMyComponent.GetSomeValue: string;
begin
  Result := 'test';
end;

function TMyComponent.GetSomeValueExt: string;
begin
  Result := 'extended..';
end;

如何让我的组件在名为 MyProperties 的类别下使用 SomeValue 和 SomeValueExt 在 Object Inspector 中注册？

插图：

我的组件可能有很多已发布的属性，我希望它们位于对象检查器的自己级别子类别下，以使其远离名称和标签等常见属性。

谢谢:)

Answer 1

创建一个具有这些属性的类，然后为您的组件提供该类类型的单个属性。属性类应该是 TPersistent 后代：

type
  TComponentProperties = class(TPersistent)
  private
    function GetSomeValue: string;
    function GetSomeValueExt: string;
  published
    property SomeValue: string read GetSomeValue;
    property SomeValueExt: string read GetSomeValueExt;
  end;

  TMyComponent = class(TComponent)
  private
    FProperties: TComponentProperties;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Properties: TComponentProperties read FProperties;
  end;

组件拥有自己的属性对象，所以需要创建和销毁：

constructor TMyComponent.Create;
begin
  inherited;
  FProperties := TComponentProperties.Create;
end;

destructor TMyComponent.Destroy;
begin
  FProperties.Free;
  inherited;
end;

使用该代码，组件的属性现在应该列在“属性”项下。不过，它不是一个类别。类别完全是另一回事。类别不会重新排列组件；它们只是更改属性在对象检查器中的显示方式。请注意，在我的代码中，TMyComponent 不再具有任何 SomeValue 属性。相反，它只有一个属性Properties，而那个 对象还有其他属性。考虑这是否真的是您希望组件的使用者必须访问它的方式。

---

如果Properties属性不是只读的，那么它需要有一个属性设置器；你不能让它直接写给FProperties。像这样写：

procedure TMyComponent.SetProperties(const Value: TProperties);
begin
  FProperties.Assign(Value);
end;

这也要求您重写 Assign 方法来做正确的事情：

procedure TComponentProperties.Assign(Other: TPersistent);
begin
  if Other is TComponentProperties then begin
    SomeValue := TComponentProperties(Other).SomeValue;
    SomeValueEx := TComponentProperties(Other).SomeValueEx;
  end else
    inherited;
end;

我们还假设属性对象的属性也不是只读的。当属性对象的属性发生变化时，拥有对象可能想知道它，因此它应该有一个事件，组件为其赋值。当属性发生变化时，它们会触发事件。