对 TEdit 中的选定文本使用 Styled SysColor

Question

我正在使用 Delphi XE3 构建一个 VCL 应用程序。此 VCL 应用程序使用来自单元 Vcl.Styles 的内置样式设置样式。

在我使用 SysColor 的样式中，clHighlight 已被更改，但是当在 TEdit（或 TComboBox 或 TComboBox 或 TMemo）中选择一段文本时，将使用默认系统突出显示颜色（默认为蓝色）用于为所选文本的背景着色。

注意：其他控件将 SysColor clHighlight 用于样式中的选定项目。

问题：如何在样式中指定这种颜色？

Answer 1

这是WinApi的一个限制，这些控件使用的高亮颜色不能直接修改。唯一的解决方法是挂钩并用StyleServices.GetSystemColor 函数替换GetSysColor 方法。像这样

implementation

uses
  DDetours,
  WinApi.Windows,
  Vcl.Styles,
  Vcl.Themes;

var
  TrampolineGetSysColor:  function (nIndex: Integer): DWORD; stdcall;
  GetSysColorOrgPointer : Pointer = nil;

function InterceptGetSysColor(nIndex: Integer): DWORD; stdcall;
begin
  if StyleServices.IsSystemStyle then
   Result:= TrampolineGetSysColor(nIndex)
  else
   Result:= StyleServices.GetSystemColor(nIndex or Integer($FF000000));
end;

initialization
 if StyleServices.Available then
 begin
    GetSysColorOrgPointer := GetProcAddress(GetModuleHandle('user32.dll'), 'GetSysColor');
    @TrampolineGetSysColor := InterceptCreate(GetSysColorOrgPointer, @InterceptGetSysColor);
 end;
finalization
  if GetSysColorOrgPointer<>nil then
    InterceptRemove(@TrampolineGetSysColor);

end. 

之前

之后

顺便说一句，VCL Styles Utils 项目包括一个带有这个钩子的单元。