带有默认弹出菜单项的delphi自定义组件

Question

我使用自定义列表视图组件，我需要它有一个弹出菜单项“将数据复制到剪贴板”。如果没有分配的弹出窗口，我创建一个并添加菜单项，如果已经分配了菜单，则将该项目添加到当前弹出窗口中。试图将代码放在构造函数中，但后来我意识到，弹出菜单仍未创建或关联到我的列表视图。那么知道何时创建我的默认项目吗？

constructor TMyListView.Create(AOwner: TComponent);
var
  FpopupMenu: TPopupMenu;
begin
  inherited;
  .....
  FPopUpMenuItem := TMenuItem.Create(self);
  FPopUpMenuItem.Caption := 'Copy data to clipboard';
  FPopUpMenuItem.OnClick := PopupMenuItemClick;
  if assigned(PopupMenu) then begin
    popupMenu.Items.Add(FPopUpMenuItem);
  end
  else begin
    FpopupMenu := TPopupMenu.Create(self);
    FpopupMenu.Items.Add(FPopUpMenuItem);
    PopupMenu := FpopupMenu;
  end;
...
end;

Answer 1

接受的答案确实非常有效 - 除非您在菜单项中添加键盘快捷键。如果这样做，在以其他方式访问弹出菜单之前，这些将不起作用，因为这些项目不会被创建。 如果您需要快捷方式，最好将代码从DoContextPopup 移动到Loaded。最简单的，

procedure Loaded; override;
...
procedure Loaded; 
var 
  MI: TMenuItem;
  ItemCovered: boolean;
  i: integer;
begin
  inherited;
  if not Assigned(PopupMenu) then 
    PopupMenu:=TPopupMenu.Create(self);
  ItemCovered:=false;
  for i := 0 to PopupMenu.Items.Count-1 do
    if IsSameEvent(PopupMenu.Items[I].OnClick, CopyDataToClipboardClick) then begin 
      ItemCovered:=true;
      break;
    end;
  if not ItemCovered then begin
    MI:=TMenuItem.Create(PopupMenu);
    MI.Caption:='Copy data to clipboard';
    MI.OnClick:=CopyDataToClipboardClick;
    MI.ShortCut:=ShortCut(Ord('C'),[ssShift,ssCtrl]);
    PopupMenu.Items.Add(MI);
  end;
end;

这不会检查在运行时添加的弹出菜单，但可能更适合大多数情况。

Answer 2

覆盖虚拟TControl.DoContextPopup()方法，例如：

type
  TMyListView = class(TListView)
  protected
    ...
    procedure DoContextPopup(MousePos: TPoint; var Handled: Boolean); override;
    ...
  end;

procedure TMyListView.DoContextPopup(MousePos: TPoint; var Handled: Boolean);
var
  LPopupMenu: TPopupMenu;
  LItem: TMenuItem;

  function IsSameEvent(const E1, E2: TNotifyEvent): Boolean;
  begin
    Result := (TMethod(E1).Code = TMethod(E2).Code) and
              (TMethod(E1).Data = TMethod(E2).Data);
  end;

begin
  inherited DoContextPopup(MousePos, Handled);
  if Handled then Exit;

  LPopupMenu := PopupMenu;
  if not Assigned(LPopupMenu) then
  begin
    LPopupMenu := TPopupMenu.Create(Self);
    PopupMenu := LPopupMenu;
  end;

  for I := 0 to LPopupMenu.Items.Count-1 do
  begin
    LItem := LPopupMenu.Items[I];
    if IsSameEvent(LItem.OnClick, PopupMenuItemClick) then
      Exit;
  end;

  LItem := TMenuItem.Create(Self);
  LItem.Caption := 'Copy data to clipboard';
  LItem.OnClick := PopupMenuItemClick;
  LPopupMenu.Items.Add(LItem);
end;