如何制作圆角的TFrame？

Question

我想制作一个基于TFrame 和TLMDShapeControl（用于绘制圆角背景）和TEdit 控件（也可以是TComboBox 或TDBEdit 等）的组件. 之后我将使用“Add to Palette”命令将它变成一个可重用的组件控件。

问题在于我需要它的宽度是灵活的，为此我想到了将框架alClient 和TEdit 内的所有内容以5 像素的边距转动，以便用户可以看到圆角。

这太糟糕了，因为我不能使用Align 并将组件设置在另一个顶部。现在我每次必须使用它时都必须复制并粘贴组件！ :-(((

我认为正确的唯一方法是仅使用 TEdit 和 alClient 和 5px 边距，而不使用 TShape。相反，我可以将TFrame 设置为具有透明度的圆角，这样在使用不同颜色或TImages 时它不会显得难看。

但是我该怎么做呢？

有人有代码示例吗？

Answer 1

要回答你的问题如何制作圆角框架，你可以尝试这样的方法，但你会对结果不满意，因为这里使用的CreateRoundRectRgn 没有抗锯齿。

type
  TFrame1 = class(TFrame)
    Edit1: TEdit;
    Button1: TButton;
  protected
    procedure SetBounds(ALeft, ATop, AWidth, AHeight: Integer); override;
  end;

implementation

procedure TFrame1.SetBounds(ALeft, ATop, AWidth, AHeight: Integer);
var
  Region: HRGN;
begin
  inherited;
  Region := CreateRoundRectRgn(0, 0, ClientWidth, ClientHeight, 30, 30);
  SetWindowRgn(Handle, Region, True);
end;

更新：

由于 GDI 没有任何支持弧形渲染的抗锯齿功能，我在这里发布了一个使用 GDI+ 的圆角矩形形状（只是一个纯实心圆角矩形）的示例（为此，您将需要 GDI+ 包装器） from here)。

以下属性对其使用很重要：

• 颜色 - 是形状填充颜色（可以增强笔颜色、渐变等）
• Radius - 是用于绘制圆角的圆的​​半径（以像素为单位）
• AlphaValue - 是渲染圆角矩形的不透明度值（只是为了好玩:-)

unit RoundShape;

interface

uses
  SysUtils, Classes, Controls, Graphics, GdiPlus;

type
  TCustomRoundShape = class(TGraphicControl)
  private
    FRadius: Integer;
    FAlphaValue: Integer;
    procedure SetRadius(Value: Integer);
    procedure SetAlphaValue(Value: Integer);
  protected
    procedure Paint; override;
    property Radius: Integer read FRadius write SetRadius default 10;
    property AlphaValue: Integer read FAlphaValue write SetAlphaValue default 255;
  public
    constructor Create(AOwner: TComponent); override;
  end;

  TRoundShape = class(TCustomRoundShape)
  public
    property Canvas;
  published
    property Align;
    property AlphaValue;
    property Anchors;
    property Color;
    property Constraints;
    property DragCursor;
    property DragKind;
    property DragMode;
    property Enabled;
    property Font;
    property ParentColor;
    property ParentFont;
    property ParentShowHint;
    property PopupMenu;
    property Radius;
    property ShowHint;
    property Visible;
    property OnClick;
    property OnContextPopup;
    property OnDblClick;
    property OnDragDrop;
    property OnDragOver;
    property OnEndDock;
    property OnEndDrag;
    property OnMouseActivate;
    property OnMouseDown;
    property OnMouseEnter;
    property OnMouseLeave;
    property OnMouseMove;
    property OnMouseUp;
    property OnStartDock;
    property OnStartDrag;
  end;

procedure Register;

implementation

{ TCustomRoundShape }

constructor TCustomRoundShape.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  Width := 213;
  Height := 104;
  FRadius := 10;
  FAlphaValue := 255;
end;

procedure TCustomRoundShape.SetRadius(Value: Integer);
begin
  if FRadius <> Value then
  begin
    FRadius := Value;
    Invalidate;
  end;
end;

procedure TCustomRoundShape.SetAlphaValue(Value: Integer);
begin
  if FAlphaValue <> Value then
  begin
    FAlphaValue := Value;
    Invalidate;
  end;
end;

procedure TCustomRoundShape.Paint;
var
  GPPen: TGPPen;
  GPColor: TGPColor;
  GPGraphics: IGPGraphics;
  GPSolidBrush: IGPSolidBrush;
  GPGraphicsPath: IGPGraphicsPath;
begin
  GPGraphicsPath := TGPGraphicsPath.Create;
  GPGraphicsPath.Reset;
  GPGraphicsPath.AddArc(0, 0, FRadius, FRadius, 180, 90);
  GPGraphicsPath.AddArc(ClientWidth - FRadius - 1, 0, FRadius, FRadius, 270, 90);
  GPGraphicsPath.AddArc(ClientWidth - FRadius - 1, ClientHeight - FRadius - 1,
    FRadius, FRadius, 0, 90);
  GPGraphicsPath.AddArc(0, ClientHeight - FRadius - 1, FRadius, FRadius, 90, 90);
  GPGraphicsPath.CloseFigure;

  GPColor.InitializeFromColorRef(ColorToRGB(Color));
  GPColor.Alpha := FAlphaValue;
  GPPen := TGPPen.Create(GPColor);
  GPSolidBrush := TGPSolidBrush.Create(GPColor);

  GPGraphics := TGPGraphics.Create(Canvas.Handle);
  GPGraphics.SmoothingMode := SmoothingModeAntiAlias;
  GPGraphics.FillPath(GPSolidBrush, GPGraphicsPath);
  GPGraphics.DrawPath(GPPen, GPGraphicsPath);
end;

procedure Register;
begin
  RegisterComponents('Stack Overflow', [TRoundShape]);
end;

end.

结果（应用SmoothingModeAntiAlias平滑模式）：

可以说，将 GDI+ 用于如此微小但没有抗锯齿的纯 GDI 渲染会使结果看起来很难看，这是一个很大的开销。以下是使用纯 GDI 渲染的同一个圆角矩形的示例：