使用继承的接口作为 TDictionary 中的键答案

【问题标题】：Using an inherited Interface as key in TDictionary使用继承的接口作为 TDictionary 中的键
【发布时间】：2011-12-07 20:44:18
【问题描述】：

继承的接口可以用作 TDictionary 中的键吗？

//! Note the inheritance of the interfaces
ILoggingProvider = interface
  procedure Log(AMessage : string);
end;

IHTTPLoggingProvider = interface(ILoggingProvider)      
  function Login(AUserName : string; APassword : string) : boolean
end;

ILiveLoggingProvider = interface(ILoggingProvider)
  function ConnectMonitor : boolean
end;

var
  loggers : TDictionary<ILoggingProvider,TObject>;

...

loggers.add(ILoggingProvider, TSomeLogger.Create());
loggers.add(IHTTPLoggingProvider , TSuperLogger.Create()); //fails!
loggers.add(ILiveLoggingProvider , TAnotherLogger.Create()); //fails!


 ... //and the use them selectively

if loggers.ContainsKey(IHTTPLoggingProvider ) then
  loggers.Items[IHTTPLoggingProvider].Log('Good bye world!');

... //and like this

var

  theLogger : IHTTPLoggingProvider;

if loggers.ContainsKey(IHTTPLoggingProvider ) then
begin
  theLogger := IHTTPLoggingProvider(loggers.Items[IHTTPLoggingProvider]);
  if theLogger.Login('billy', 'bones') then
    theLogger.Log('some message');
end;

【问题讨论】：

当然TDictionary<ILoggingProvider,TObject> 想要接口引用而不是接口。 TObject 到 IHTTPLoggingProvider 的演员阵容非常可疑。值类型应该是一个接口。我认为我会将密钥设为 GUID。还是我拿错了棍子的一端？
@David：正确 - 使用接口也可以工作，并且在使用纯接口方法时更加一致 - 好主意。当我声明TLoggers = TDictionary<TGUID,ILoggingProvider> 时，它会在构造“TLoggers”实例时引发异常Invalid type cast，而loggers := TDictionary<TGUID,ILoggingProvider>.Create 很好。有什么想法吗？
我的答案中的代码编译、运行和操作正确。

标签： delphi generics dictionary delphi-xe

【解决方案1】：

根据我的评论，这是我认为可以实现的方式：

type
  ILoggingProvider = interface
    ['{30598F45-1230-4208-B1A5-E1D2DA8F6D40}']
    procedure Log(AMessage : string);
  end;

  IHTTPLoggingProvider = interface(ILoggingProvider)
    ['{CFA01514-AC44-4E30-971B-115986B37D26}']
    function Login(AUserName : string; APassword : string) : boolean;
  end;

  ILiveLoggingProvider = interface(ILoggingProvider)
    ['{6EA68BEF-8D78-4FDF-AACD-1D164A272758}']
    function ConnectMonitor : boolean;
  end;

  TLoggingProvider = class(TInterfacedObject, ILoggingProvider)
    procedure Log(AMessage : string);
  end;

  THTTPLoggingProvider = class(TInterfacedObject, ILoggingProvider, IHTTPLoggingProvider)
    procedure Log(AMessage : string);
    function Login(AUserName : string; APassword : string) : boolean;
  end;

  TLiveLoggingProvider = class(TInterfacedObject, ILoggingProvider, ILiveLoggingProvider)
    procedure Log(AMessage : string);
    function ConnectMonitor : boolean;
  end;

procedure Main;
var
  loggers : TDictionary<TGUID,ILoggingProvider>;
  theLogger : IHTTPLoggingProvider;
begin
  loggers := TDictionary<TGUID,ILoggingProvider>.Create;
  try
    loggers.add(ILoggingProvider, TLoggingProvider.Create);
    loggers.add(IHTTPLoggingProvider, THTTPLoggingProvider.Create);
    loggers.add(ILiveLoggingProvider, TLiveLoggingProvider.Create);

    if loggers.ContainsKey(IHTTPLoggingProvider) then
      loggers.Items[IHTTPLoggingProvider].Log('Good bye world!');

    if loggers.ContainsKey(IHTTPLoggingProvider) then
    begin
      theLogger := loggers.Items[IHTTPLoggingProvider] as IHTTPLoggingProvider;
      if theLogger.Login('billy', 'bones') then
        theLogger.Log('some message');
    end;
  finally
    loggers.Free;
  end;
end;

【讨论】：