如何获取类型集的任何变量的元素数？

Question

AFAIK 没有内置函数。在网上搜索我发现了这个function，它对我有用，但我不想使用它，因为它是汇编，我不明白它在做什么。所以我写了这个也可以工作的函数：

function Cardinality(const PSet: PByteArray;
  const SizeOfSet(*in bytes*): Integer): Integer;
const
  Masks: array[0..7] of Byte = (1, 2, 4, 8, 16, 32, 64, 128);
var
  I, J: Integer;
begin
  Result := 0;
  for I := 0 to SizeOfSet - 1 do
    for J := 0 to 7 do
      if (PSet^[I] and Masks[J]) > 0 then
        Inc(Result);
end;

现在，我想知道我是否可以依赖此功能？或者也许 set 数据类型背后有一个技巧，这就是 delphi 没有内置方法的原因。

但是if我的功能是可靠的then我该如何改进它：

1. 将常量传递给它
2. 进行类型检查并确保将集合传递给函数
3. 传递值而不是其地址
4. 去掉SizeOfSet参数

我想将其称为Cardinality(AnySet) 而不是Cardinality(@AnySet, SizeOf(TAnySet))。

顺便说一句，我需要在 XE 和 XE5 中编译它。

Answer 1

您可以使用泛型和 RTTI 来实现这一点。像这样：

uses
  SysUtils, TypInfo;

type
  ERuntimeTypeError = class(Exception);

  TSet<T> = class
  strict private
    class function TypeInfo: PTypeInfo; inline; static;
  public
    class function IsSet: Boolean; static;
    class function Cardinality(const Value: T): Integer; static;
  end;

const
  Masks: array[0..7] of Byte = (1, 2, 4, 8, 16, 32, 64, 128);

implementation

{ TSet<T> }

class function TSet<T>.TypeInfo: PTypeInfo;
begin
  Result := System.TypeInfo(T);
end;

class function TSet<T>.IsSet: Boolean;
begin
  Result := TypeInfo.Kind=tkSet;
end;

function GetCardinality(const PSet: PByteArray;
  const SizeOfSet(*in bytes*): Integer): Integer; inline;
var
  I, J: Integer;
begin
  Result := 0;
  for I := 0 to SizeOfSet - 1 do
    for J := 0 to 7 do
      if (PSet^[I] and Masks[J]) > 0 then
        Inc(Result);
end;

class function TSet<T>.Cardinality(const Value: T): Integer;
var
  EnumTypeData: PTypeData;
begin
  if not IsSet then
    raise ERuntimeTypeError.Create('Invalid type in TSet<T>, T must be a set');
  Result := GetCardinality(PByteArray(@Value), SizeOf(Value));
end;

用法：

Writeln(TSet<SomeSet>.Cardinality(Value));

Answer 2

在早期版本的 Delphi 中，您可以这样做：

function Card(ASet: TSet): Integer;
var
  k: TSetElement;
begin
  Result := 0;
  for k in ASet do Inc(Result);
end;