在终结中使用私有方法/var

Question

我有（静态）类 GT_MyClass

GT_MyClass = class
private
  class var FImage : TJpegImage;

  class function GetImage: TJpegImage;
public
  property Image : TJpegImage  read GetImage;
end;

在 GetImage 函数中，如果 FImage 尚不存在，我将创建它。

class function GT_Myclass.GetImage: TJpegImage;
begin
    if not Assigned(FImage) then
    begin
      FImage := TJpegImage.Create;
    end;
    Result := FImage;
end;

最后我想 FreeAndNil(FImage)

finalization
  if Assigned(FImage) then
    FreeAndNil(FImage);

但在完成块中我看不到 private var FImage...

你能帮帮我吗？

谢谢！

顺便说一句：我想让 Image 绝对是静态的

Answer 1

这是由于范围不同。在类方法中，GT_MyClass.GetImage 您的代码在类的范围内，因此可以看到类成员。终结部分在全局范围内执行。所以你可以通过限定名称来编译你的代码：

finalization
  if Assigned(GT_MyClass.FImage) then
    FreeAndNil(GT_MyClass.FImage);

事实上，测试分配GT_MyClass.FImage 是没有意义的，因为Free 已经这样做了。所以你会写：

finalization
  FreeAndNil(GT_MyClass.FImage);

或者你可以提供另一个类的方法来更好地封装它：

type
  GT_MyClass = class
  private
    class var FImage : TJpegImage;
    class function GetImage: TJpegImage;
    class procedure Finalize;
  public
    property Image : TJpegImage  read GetImage;
  end;
....
class procedure GT_MyClass.Finalize;
begin
  FreeAndNil(FImage); // in scope of class, no need to qualify
end;
....
finalization
  GT_MyClass.Finalize;

但这仍然会让您从类外部调用私有方法，这并不理想。所以你可以使用class destructor，它是从单元的最终代码中执行的：

type
  GT_MyClass = class
  private
    class var FImage : TJpegImage;
    class function GetImage: TJpegImage;
    class destructor ClassDestroy;
  public
    property Image : TJpegImage  read GetImage;
  end;
....
class destructor GT_MyClass.ClassDestroy;
begin
  FreeAndNil(FImage); // in scope of class, no need to qualify
end;

不需要终结代码，编译器会自动确保调用了类析构函数。