Mojolicious 重用先前建立的连接

Question

我正在尝试重用以前建立的 websocket 连接以避免 websocket 握手。我发现可以使用build_websocket_tx（更多细节here）构建自定义websocket事务，并且每个websocket连接都有一个连接标识符，可以使用Mojo::Transaction中定义的connection子例程检索（更多细节@987654322 @)。我可以以某种方式将这两者结合起来重新使用连接吗？还有其他方法吗？

PS：Websocket 连接应该是一致的和可重用的。但是 Mojolicoious 没有为 websocket 连接提供任何此类选项。

编辑

没有连接重用的示例代码。

#!/usr/bin/perl

use strict;
use warnings;

use Mojo::UserAgent;
use JSON qw |encode_json|;

my $ua = Mojo::UserAgent->new;
my $url = "wss://trello.com/1/Session/socket";

$| = 1;

sub _connect {
    my $req = {
        type => "ping",
        reqid=> 0
    };
    $ua->websocket(
        $url => sub {
            my ($ua, $tx) = @_;

            die "error: ", $tx->res->error->{message}, "\n" if $tx->res->error;
            die 'Not a websocket connection' unless $tx->is_websocket;

            # Connection established.
            $tx->on(
                message => sub {
                    my ($tx, $msg) = @_;
                    print "$msg\n";
                    $tx->closed; #Close connection
                });
            $tx->send(encode_json($req));
        });
}

sub reuse_conn {
    # Re use connection
}

_connect();

Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

Answer 1

预备：运行带有调试信息的 Mojolicious 客户端脚本：

MOJO_EVENTEMITTER_DEBUG=1 MOJO_USERAGENT_DEBUG=1 perl mua.pl

在版本 7.43 中，Mojo::UserAgent 具有 built-in connection pooling 但 specifically refuses to use it for WebSockets。这很可能是因为正如您所说，WebSockets 是有状态的，如果 UserAgent 盲目地重用连接，那可能会导致混乱。但是，如果您的应用程序知道如何安全地重用它们，那就另当别论了。

这个问题最近出现在 Mojolicious 的 IRC 频道，sri, the author, said：

16:28 sri mohawk：一些框架，如 phoenix，在 websockets 之上有自己的更高级别的协议来多路复用多个通道 https://hexdocs.pm/phoenix/channels.html 16:28 听起来这就是你想要的 16:28 mojolicious 应该有类似的东西，但还没有 [...] 16:42 sri 建立在 mojolicious 之上并不难，但现在你必须自己做 16:42 最终我希望我们将它放在核心中，没有消息总线部分 16:43 但频道管理和路由 [...] 16:50 jberger mohawk 我确实写了 Mojolicious::Plugin::Multiplex 这可能会有所帮助 16:51 更高级别工具的示例

我承认 OP 说：

我能够重用连接的唯一方法是存储事务对象并在后续调用中使用它。

但是，就目前的代码而言，这似乎是唯一的方法。此代码演示了如何创建、维护和使用您自己的连接池：

#!/usr/bin/perl

use strict;
use warnings;
use Mojo::UserAgent;
use Time::HiRes qw(time);
$| = 1;
my $REQ = {
    type => "ping",
    reqid => 0,
};
my $URL = "wss://trello.com/1/Session/socket";
my $SECONDS = 2;
my $POOL_SIZE = 5;

my $ua = Mojo::UserAgent->new;
my @pool;

sub make_conn {
  my ($ua, $url, $pool) = @_;
  $ua->websocket($URL => sub {
    my (undef, $tx) = @_;
    die "error: ", $tx->res->error->{message}, "\n" if $tx->res->error;
    die 'Not a websocket connection' unless $tx->is_websocket;
    push @$pool, $tx;
  });
}

# pool gets pushed onto, shifted off, so using recently-used connection
sub send_message {
  my ($pool, $request, $start) = @_;
  my $tx = shift @$pool;
  die "got bad connection" unless $tx; # error checking needs improving
  $tx->once(message => sub {
    my (undef, $msg) = @_;
    print "got back: $msg\n";
print "took: ", time - $start, "\n";
    push @$pool, $tx;
  });
  $tx->send({json => $request});
}

make_conn($ua, $URL, \@pool) for (1..5); # establish pool

# every 2 secs, send a message
my $timer_cb;
$timer_cb = sub {
  my $loop = shift;
  print "every $SECONDS\n";
  send_message(\@pool, $REQ, time);
  $loop->timer($SECONDS => $timer_cb);
};
Mojo::IOLoop->timer($SECONDS => $timer_cb);

Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

在高层次上，它是这样工作的：

• 在池中建立 5 个连接
• send_message 使用该池中最近最少使用的连接
• 每两秒发送一条消息，注册一次“on message”回调来处理响应

为简单起见，它不会在从池中获取连接时检查它们是否仍在工作，而是依靠前两秒的延迟来初始化所有 5 个连接。

time 调用的使用展示了使用此池的速度增益。您提供的代码（在我的系统上）大约需要 300 毫秒来启动连接，然后发送和接收。使用池，大约需要 120 毫秒。