使用 SendMessage API 检索 ComboBox 计数和项目

Question

我想获得不属于我的ComboBox 控件的计数和列表，因此我无法修改代码。

例如，可以使用SendMessage API 来控制目标应用程序。

但是，我怎样才能通过挂钩来检索目标控件的整个列表？

Answer 1

您可以在此处找到ComboBox 控制消息的列表：

• MSDN - ComboBox Control Messages
• PInvoke - CB_ Constants

要获取项目计数，您需要使用 CB_GETCOUNT 消息，要获取项目的文本，您可以使用 CB_GETLBTEXT 消息。

示例

在这里我创建了一个ComboBoxHelper 类，您可以通过传递ComboBox 的Handle 并使用它的属性来创建它的实例：

• SelectedIndex as Integer：返回选择的索引，如果没有选择项返回 -1。
• Selectedtext as String：返回所选项目的文本，如果没有选择项目，则返回 String.Empty。
• ItemsCount as Integer：返回项目数。
• Items(index) as String：返回指定项的文本（指定索引处的项）
• Items as List(of String)：返回组合框的项目列表。如果没有项目，则返回一个空列表。

Public Class ComboBoxHelper
    Private hWnd As IntPtr
    Const CB_GETCURSEL As Integer = &H147
    Const CB_SETCURSEL As Integer = &H14E
    Const CB_GETCOUNT As Integer = &H146
    Const CB_GETLBTEXT As Integer = &H148
    Const CB_GETLBTEXTLEN As Integer = &H149
    <System.Runtime.InteropServices.DllImport("user32.dll")> _
    Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As Integer, _
        ByVal wParam As Integer, ByRef lParam As Integer) As IntPtr
    End Function
    <System.Runtime.InteropServices.DllImport("user32.dll")> _
    Shared Function SendMessage(ByVal hWnd As IntPtr, ByVal Msg As Integer, _
        ByVal wParam As Integer, ByVal lParam As System.Text.StringBuilder) As IntPtr
    End Function
    Public Sub New(handle As IntPtr)
        hWnd = handle
    End Sub
    Public Property SelectedIndex As Integer
        Get
            Return SendMessage(hWnd, CB_GETCURSEL, 0, 0).ToInt32()
        End Get
        Set(ByVal value As Integer)
            SendMessage(hWnd, CB_SETCURSEL, value, 0).ToInt32()
        End Set
    End Property
    Public ReadOnly Property ItemsCount As Integer
        Get
            Return SendMessage(hWnd, CB_GETCOUNT, 0, 0).ToInt32()
        End Get
    End Property
    Public ReadOnly Property SelectedText As String
        Get
            Dim index = Me.SelectedIndex
            If (Me.SelectedIndex = -1) Then
                Return String.Empty
            End If
            Return Me.Items(index)
        End Get
    End Property
    Public ReadOnly Property Items() As List(Of String)
        Get
            If (ItemsCount > 0) Then
                Return Enumerable.Range(0, ItemsCount) _
                                 .Select(Function(index) Items(index)).ToList()
            Else
                Return New List(Of String)
            End If
        End Get
    End Property
    Public ReadOnly Property Items(index As Integer) As String
        Get
            If (index < 0 OrElse index >= ItemsCount) Then
                Throw New ArgumentOutOfRangeException("index")
            End If
            Dim length = SendMessage(hWnd, CB_GETLBTEXTLEN, index, 0).ToInt32()
            Dim text As New System.Text.StringBuilder(length)
            SendMessage(hWnd, CB_GETLBTEXT, index, text)
            Return text.ToString()
        End Get
    End Property
End Class

以下是该类的使用示例：

Dim combo As New ComboBoxHelper(hWnd) 'You have hWnd
MessageBox.Show(combo.ItemsCount.ToString())
MessageBox.Show(combo.SelectedIndex.ToString())
MessageBox.Show(combo.SelectedText.ToString())
combo.Items.ForEach(Function(item) MessageBox.Show(item))